1 files changed, 38 insertions, 0 deletions
diff --git a/src/plugins/shellintegration/ivi-shell/ivi-shell.pro b/src/plugins/shellintegration/ivi-shell/ivi-shell.pro
new file mode 100644
index 000000000..8fd774736
--- /dev/null
+++ b/src/plugins/shellintegration/ivi-shell/ivi-shell.pro
@@ -0,0 +1,38 @@
+PLUGIN_TYPE = wayland-shell-integration
+load(qt_plugin)
+
+QT += waylandclient-private
+CONFIG += wayland-scanner
+
+!contains(QT_CONFIG, no-pkg-config) {
+    PKGCONFIG += wayland-client wayland-cursor
+    CONFIG += link_pkgconfig
+} else {
+    LIBS += -lwayland-client -lwayland-cursor
+}
+
+config_xkbcommon {
+    !contains(QT_CONFIG, no-pkg-config) {
+        PKGCONFIG += xkbcommon
+    } else {
+        LIBS += -lxkbcommon
+    }
+} else {
+    DEFINES += QT_NO_WAYLAND_XKB
+}
+
+WAYLANDCLIENTSOURCES += \
+    ../../../3rdparty/protocol/ivi-application.xml \
+    ../../../3rdparty/protocol/ivi-controller.xml
+
+HEADERS += \
+    qwaylandivishellintegration.h \
+    qwaylandivisurface_p.h
+
+SOURCES += \
+    main.cpp \
+    qwaylandivishellintegration.cpp \
+    qwaylandivisurface.cpp
+
+OTHER_FILES += \
+    ivi-shell.json