examples/wayland/multi-output/qml/main.qml


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

// Copyright (C) 2017 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause

import QtQuick
import QtWayland.Compositor
import QtWayland.Compositor.XdgShell
import QtWayland.Compositor.WlShell

WaylandCompositor {
    id: comp

    defaultOutput: shellScreen
    ShellScreen {
        id: shellScreen
        compositor: comp
    }

    GridScreen {
        id: gridScreen
        compositor: comp
    }

    Component {
        id: chromeComponent
        ShellChrome {
        }
    }

    Component {
        id: surfaceComponent
        WaylandSurface {
            id: surface
            signal activated()
            onHasContentChanged: {
                if (hasContent && !cursorSurface) {
                    gridScreen.gridSurfaces.append( { "gridSurface" : surface } );
                } else {
                    for (var i = 0; i < gridScreen.gridSurfaces.count; i++) {
                        if (gridScreen.gridSurfaces.get(i).gridSurface === surface) {
                            gridScreen.gridSurfaces.remove(i,1);
                            break;
                        }
                    }
                }
            }
        }
    }

    XdgOutputManagerV1 {}

    // ![xdgshell]
    XdgShell {
        onToplevelCreated: {
            var item = chromeComponent.createObject(defaultOutput.surfaceArea, { "shellSurface": xdgSurface } );
            item.surface.activated.connect(item.raise);
        }
    }
    // ![xdgshell]

    // ![onSurfaceRequested]
    onSurfaceRequested: {
        var surface = surfaceComponent.createObject(comp, { } );
        surface.initialize(comp, client, id, version);
    }
    // ![onSurfaceRequested]
}