blob: 251d757e2a85634eb1ee77bb81cec0c45bdd63c3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
TARGET = QtWaylandCompositor
MODULE = waylandcompositor
QT = core gui-private
qtHaveModule(quick): QT += quick
contains(QT_CONFIG, opengl):MODULE_DEFINES = QT_WAYLAND_COMPOSITOR_GL
CONFIG -= precompile_header
CONFIG += link_pkgconfig
DEFINES += QT_WAYLAND_WINDOWMANAGER_SUPPORT
QMAKE_DOCS = $$PWD/doc/qtwaylandcompositor.qdocconf
!contains(QT_CONFIG, no-pkg-config) {
PKGCONFIG_PRIVATE += wayland-server
} else {
LIBS += -lwayland-server
}
INCLUDEPATH += ../shared
HEADERS += ../shared/qwaylandmimehelper_p.h \
../shared/qwaylandinputmethodeventbuilder_p.h \
../shared/qwaylandsharedmemoryformathelper_p.h
SOURCES += ../shared/qwaylandmimehelper.cpp \
../shared/qwaylandinputmethodeventbuilder.cpp
RESOURCES += compositor.qrc
include ($$PWD/global/global.pri)
include ($$PWD/wayland_wrapper/wayland_wrapper.pri)
include ($$PWD/hardware_integration/hardware_integration.pri)
include ($$PWD/compositor_api/compositor_api.pri)
include ($$PWD/extensions/extensions.pri)
MODULE_PLUGIN_TYPES = \
wayland-graphics-integration-server
load(qt_module)
|
