Only deploy ffmpegsumo once in debug_and_release

This moves all installs inside the the release-only-with-debug-fallback
block to prevent the debug ffmpegsumo.dll to overwrite the release
one on Windows (and get use for both debug and release builds).

This will use the release version for both instead by default.

This also moves the load(qt_module) call higher to make sure that
build_all is added to CONFIG at that point.

Change-Id: I2584a28e5eaaf5028798703fb387ac2b120d7ea9
Task-number: QTBUG-43348
Reviewed-by: Simon Hausmann <simon.hausmann@digia.com>

1 files changed, 53 insertions, 51 deletions

diff --git a/src/core/core_module.pro b/src/core/core_module.pro
index 14f249142..8e445bd3a 100644
--- a/src/core/core_module.pro
+++ b/src/core/core_module.pro
@@ -12,6 +12,18 @@ QMAKE_INFO_PLIST = Info_mac.plist
     error("Could not find the linking information that gyp should have generated.")
 }
 
+# We distribute the module binary but headers are only available in-tree.
+CONFIG += no_module_headers
+load(qt_module)
+
+# Using -Wl,-Bsymbolic-functions seems to confuse the dynamic linker
+# and doesn't let Chromium get access to libc symbols through dlsym.
+CONFIG -= bsymbolic_functions
+
+contains(QT_CONFIG, egl): CONFIG += egl
+
+linux: contains(QT_CONFIG, separate_debug_info): QMAKE_POST_LINK="cd $(DESTDIR) && $(STRIP) --strip-unneeded $(TARGET)"
+
 REPACK_DIR = $$OUT_PWD/$$getConfigDir()/gen/repack
 # Duplicated from resources/resources.gyp
 LOCALE_LIST = am ar bg bn ca cs da de el en-GB en-US es-419 es et fa fi fil fr gu he hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv sw ta te th tr uk vi zh-CN zh-TW
@@ -31,58 +43,48 @@ icu.files = $$OUT_PWD/$$getConfigDir()/icudtl.dat
 
 plugins.files = $$OUT_PWD/$$getConfigDir()/$${PLUGIN_PREFIX}ffmpegsumo$${PLUGIN_EXTENSION}
 
-!debug_and_release|!build_all|CONFIG(release, debug|release):contains(QT_CONFIG, qt_framework) {
-    locales.version = Versions
-    locales.path = Resources/qtwebengine_locales
-    resources.version = Versions
-    resources.path = Resources
-    icu.version = Versions
-    icu.path = Resources
-    plugins.version = Versions
-    plugins.path = Libraries
-    # No files, this prepares the bundle Helpers symlink, process.pro will create the directories
-    qtwebengineprocessplaceholder.version = Versions
-    qtwebengineprocessplaceholder.path = Helpers
-    QMAKE_BUNDLE_DATA += icu locales resources plugins qtwebengineprocessplaceholder
-} else {
-    locales.CONFIG += no_check_exist
-    locales.path = $$[QT_INSTALL_TRANSLATIONS]/qtwebengine_locales
-    resources.CONFIG += no_check_exist
-    resources.path = $$[QT_INSTALL_DATA]
-    icu.CONFIG += no_check_exist
-    icu.path = $$[QT_INSTALL_DATA]
-    plugins.CONFIG += no_check_exist
-    plugins.path = $$[QT_INSTALL_PLUGINS]/qtwebengine
-    INSTALLS += icu locales resources plugins
-}
-
-# We distribute the module binary but headers are only available in-tree.
-CONFIG += no_module_headers
-load(qt_module)
-
-# Using -Wl,-Bsymbolic-functions seems to confuse the dynamic linker
-# and doesn't let Chromium get access to libc symbols through dlsym.
-CONFIG -= bsymbolic_functions
-
-contains(QT_CONFIG, egl): CONFIG += egl
-
-linux: contains(QT_CONFIG, separate_debug_info): QMAKE_POST_LINK="cd $(DESTDIR) && $(STRIP) --strip-unneeded $(TARGET)"
+!debug_and_release|!build_all|CONFIG(release, debug|release) {
+    contains(QT_CONFIG, qt_framework) {
+        locales.version = Versions
+        locales.path = Resources/qtwebengine_locales
+        resources.version = Versions
+        resources.path = Resources
+        icu.version = Versions
+        icu.path = Resources
+        plugins.version = Versions
+        plugins.path = Libraries
+        # No files, this prepares the bundle Helpers symlink, process.pro will create the directories
+        qtwebengineprocessplaceholder.version = Versions
+        qtwebengineprocessplaceholder.path = Helpers
+        QMAKE_BUNDLE_DATA += icu locales resources plugins qtwebengineprocessplaceholder
+    } else {
+        locales.CONFIG += no_check_exist
+        locales.path = $$[QT_INSTALL_TRANSLATIONS]/qtwebengine_locales
+        resources.CONFIG += no_check_exist
+        resources.path = $$[QT_INSTALL_DATA]
+        icu.CONFIG += no_check_exist
+        icu.path = $$[QT_INSTALL_DATA]
+        plugins.CONFIG += no_check_exist
+        plugins.path = $$[QT_INSTALL_PLUGINS]/qtwebengine
+        INSTALLS += icu locales resources plugins
+    }
 
-!contains(QT_CONFIG, qt_framework): contains(QT_CONFIG, private_tests) {
-    ICU_TARGET = $$shell_path($$[QT_INSTALL_DATA]/icudtl.dat)
-    ICU_FILE = $$shell_path($$OUT_PWD/$$getConfigDir()/icudtl.dat)
-    icu_rule.target = $$ICU_TARGET
-    unix: icu_rule.commands = if [ -e $$ICU_FILE ] ; then $$QMAKE_COPY $$ICU_FILE $$ICU_TARGET ; fi
-    win32: icu_rule.commands = if exist $$ICU_FILE ( $$QMAKE_COPY $$ICU_FILE $$ICU_TARGET )
+    !contains(QT_CONFIG, qt_framework): contains(QT_CONFIG, private_tests) {
+        ICU_TARGET = $$shell_path($$[QT_INSTALL_DATA]/icudtl.dat)
+        ICU_FILE = $$shell_path($$OUT_PWD/$$getConfigDir()/icudtl.dat)
+        icu_rule.target = $$ICU_TARGET
+        unix: icu_rule.commands = if [ -e $$ICU_FILE ] ; then $$QMAKE_COPY $$ICU_FILE $$ICU_TARGET ; fi
+        win32: icu_rule.commands = if exist $$ICU_FILE ( $$QMAKE_COPY $$ICU_FILE $$ICU_TARGET )
 
-    PLUGIN_DIR = $$shell_path($$[QT_INSTALL_PLUGINS]/qtwebengine)
-    PLUGIN_TARGET = $$shell_path($$PLUGIN_DIR/$${PLUGIN_PREFIX}ffmpegsumo$${PLUGIN_EXTENSION})
-    PLUGIN_FILE = $$shell_path($$OUT_PWD/$$getConfigDir()/$${PLUGIN_PREFIX}ffmpegsumo$${PLUGIN_EXTENSION})
-    plugins_rule.target = $$PLUGIN_TARGET
-    unix: plugins_rule.commands = $$QMAKE_MKDIR $$PLUGIN_DIR && if [ -e $$PLUGIN_FILE ] ; then $$QMAKE_COPY $$PLUGIN_FILE $$PLUGIN_TARGET ; fi
-    win32: plugins_rule.commands = (if not exist $$PLUGIN_DIR ( $$QMAKE_MKDIR $$PLUGIN_DIR )) && \
-                                    if exist $$PLUGIN_FILE ( $$QMAKE_COPY $$PLUGIN_FILE $$PLUGIN_TARGET )
+        PLUGIN_DIR = $$shell_path($$[QT_INSTALL_PLUGINS]/qtwebengine)
+        PLUGIN_TARGET = $$shell_path($$PLUGIN_DIR/$${PLUGIN_PREFIX}ffmpegsumo$${PLUGIN_EXTENSION})
+        PLUGIN_FILE = $$shell_path($$OUT_PWD/$$getConfigDir()/$${PLUGIN_PREFIX}ffmpegsumo$${PLUGIN_EXTENSION})
+        plugins_rule.target = $$PLUGIN_TARGET
+        unix: plugins_rule.commands = $$QMAKE_MKDIR $$PLUGIN_DIR && if [ -e $$PLUGIN_FILE ] ; then $$QMAKE_COPY $$PLUGIN_FILE $$PLUGIN_TARGET ; fi
+        win32: plugins_rule.commands = (if not exist $$PLUGIN_DIR ( $$QMAKE_MKDIR $$PLUGIN_DIR )) && \
+                                        if exist $$PLUGIN_FILE ( $$QMAKE_COPY $$PLUGIN_FILE $$PLUGIN_TARGET )
 
-    QMAKE_EXTRA_TARGETS += icu_rule plugins_rule
-    PRE_TARGETDEPS += $$ICU_TARGET $$PLUGIN_TARGET
+        QMAKE_EXTRA_TARGETS += icu_rule plugins_rule
+        PRE_TARGETDEPS += $$ICU_TARGET $$PLUGIN_TARGET
+    }
 }