Deploy external data in QtWebEngineCore.framework for framework builds

There is currently no convenient way to deploy QtWebEngine into an application
bundle on OSX. macdeployqt copies frameworks into a .app bundle's Frameworks
directory but this makes no sense unless all the needed files are also
distributed with the bundle.

This patch moves:
- The ffmpegsumo.so library into Libraries/
- Locale .pak files, qtwebengine_resources.pak and icudtl.dat into Resources/
- QtWebEngineProcess into its own .app bundle, itself into Helpers/

QMAKE_BUNDLE_DATA is used to copy files into the bundle while INSTALLS is
used when installing normally. A LOCALE_LIST is explicitly listed since
QMAKE_BUNDLE_DATA can't handle the * glob to match all source files.

Change-Id: I5c0df57b4b9e93f9cce34a74a6e024bf90d37b5c
Task-number: QTBUG-41611
Reviewed-by: Zeno Albisser <zeno.albisser@digia.com>
Reviewed-by: Andras Becsi <andras.becsi@digia.com>

1 files changed, 32 insertions, 11 deletions

diff --git a/src/core/core_module.pro b/src/core/core_module.pro
index 3ba65e301..66ab3ee4d 100644
--- a/src/core/core_module.pro
+++ b/src/core/core_module.pro
@@ -6,18 +6,21 @@ CMAKE_MODULE_TESTS = "-"
 QT += qml quick
 QT_PRIVATE += gui-private
 
+# Needed to set a CFBundleIdentifier
+QMAKE_INFO_PLIST = Info_mac.plist
+
 # Look for linking information produced by gyp for our target according to core_generated.gyp
 !include($$OUT_PWD/$$getConfigDir()/$${TARGET}_linking.pri) {
     error("Could not find the linking information that gyp should have generated.")
 }
 
 REPACK_DIR = $$OUT_PWD/$$getConfigDir()/gen/repack
-locales.files = "$$REPACK_DIR/qtwebengine_locales/*"
-locales.CONFIG += no_check_exist
-locales.path = $$[QT_INSTALL_TRANSLATIONS]/qtwebengine_locales
+# Duplicated from resources/resources.gyp
+LOCALE_LIST = am ar bg bn ca cs da de el en-GB en-US es-419 es et fa fi fil fr gu he hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv sw ta te th tr uk vi zh-CN zh-TW
+for(LOC, LOCALE_LIST) {
+    locales.files += $$REPACK_DIR/qtwebengine_locales/$${LOC}.pak
+}
 resources.files = $$REPACK_DIR/qtwebengine_resources.pak
-resources.CONFIG += no_check_exist
-resources.path = $$[QT_INSTALL_DATA]
 
 PLUGIN_EXTENSION = .so
 PLUGIN_PREFIX = lib
@@ -26,16 +29,34 @@ win32 {
     PLUGIN_EXTENSION = .dll
     PLUGIN_PREFIX =
 }
-
 icu.files = $$OUT_PWD/$$getConfigDir()/icudtl.dat
-icu.CONFIG += no_check_exist
-icu.path = $$[QT_INSTALL_DATA]
 
 plugins.files = $$OUT_PWD/$$getConfigDir()/$${PLUGIN_PREFIX}ffmpegsumo$${PLUGIN_EXTENSION}
-plugins.CONFIG += no_check_exist
-plugins.path = $$[QT_INSTALL_PLUGINS]/qtwebengine
 
-INSTALLS += icu locales resources plugins
+!debug_and_release|!build_all|CONFIG(release, debug|release):contains(QT_CONFIG, qt_framework) {
+    locales.version = Versions
+    locales.path = Resources/qtwebengine_locales
+    resources.version = Versions
+    resources.path = Resources
+    icu.version = Versions
+    icu.path = Resources
+    plugins.version = Versions
+    plugins.path = Libraries
+    # No files, this prepares the bundle Helpers symlink, process.pro will create the directories
+    qtwebengineprocessplaceholder.version = Versions
+    qtwebengineprocessplaceholder.path = Helpers
+    QMAKE_BUNDLE_DATA += icu locales resources plugins qtwebengineprocessplaceholder
+} else {
+    locales.CONFIG += no_check_exist
+    locales.path = $$[QT_INSTALL_TRANSLATIONS]/qtwebengine_locales
+    resources.CONFIG += no_check_exist
+    resources.path = $$[QT_INSTALL_DATA]
+    icu.CONFIG += no_check_exist
+    icu.path = $$[QT_INSTALL_DATA]
+    plugins.CONFIG += no_check_exist
+    plugins.path = $$[QT_INSTALL_PLUGINS]/qtwebengine
+    INSTALLS += icu locales resources plugins
+}
 
 # We distribute the module binary but headers are only available in-tree.
 CONFIG += no_module_headers