1 files changed, 150 insertions, 0 deletions
diff --git a/mkspecs/features/platform.prf b/mkspecs/features/platform.prf
new file mode 100644
index 000000000..0b0bb6746
--- /dev/null
+++ b/mkspecs/features/platform.prf
@@ -0,0 +1,150 @@
+include($$QTWEBENGINE_OUT_ROOT/qtwebengine-config.pri)
+QT_FOR_CONFIG += webengine-private
+
+defineTest(isQtMinimum) {
+    !equals(QT_MAJOR_VERSION, $$1): return(false)
+    count(ARGS, 1, greaterThan) {
+        lessThan(QT_MINOR_VERSION, $$2): return(false)
+    }
+    return(true)
+}
+
+defineTest(isPlatformSupported) {
+  QT_FOR_CONFIG += gui-private
+  linux {
+    if(!gcc:!clang)|intel_icc {
+      skipBuild("Qt WebEngine on Linux requires clang or GCC.")
+      return(false)
+    }
+    gcc:!clang:!isGCCVersionSupported(): return(false)
+  } else:win32 {
+    winrt {
+      skipBuild("WinRT is not supported.")
+      return(false)
+    }
+    isBuildingOnWin32() {
+      skipBuild("Qt WebEngine on Windows must be built on a 64-bit machine.")
+    }
+    !msvc|intel_icl {
+      skipBuild("Qt WebEngine on Windows requires MSVC.")
+      return(false)
+    }
+    !isMinWinSDKVersion(10, 10586): {
+      skipBuild("Qt WebEngine on Windows requires a Windows SDK version 10.0.10586 or newer.")
+      return(false)
+    }
+    !qtConfig(winversion) {
+         skipBuild("Needs VS 2015 Update 3 with Cumulative Servicing Release or higher")
+         return(false)
+    }
+  } else:osx {
+    lessThan(QMAKE_XCODE_VERSION, 7.3) {
+      skipBuild("Using Xcode version $$QMAKE_XCODE_VERSION, but at least version 7.3 is required to build Qt WebEngine.")
+      return(false)
+    }
+    !clang|intel_icc {
+        skipBuild("Qt WebEngine on macOS requires Clang.")
+        return(false)
+    }
+    # We require macOS 10.11 (darwin version 15.0.0) or newer.
+    darwin_major_version = $$section(QMAKE_HOST.version, ., 0, 0)
+    lessThan(darwin_major_version, 15) {
+      skipBuild("Building Qt WebEngine requires macOS version 10.11 or newer.")
+      return(false)
+    }
+    !isMinOSXSDKVersion(10, 10): {
+      skipBuild("Building Qt WebEngine requires a macOS SDK version of 10.11 or newer. Current version is $${WEBENGINE_OSX_SDK_PRODUCT_VERSION}.")
+      return(false)
+    }
+  } else {
+    skipBuild("Unknown platform. Qt WebEngine only supports Linux, Windows, and macOS.")
+    return(false)
+  }
+
+  !contains(QT_CONFIG, c++11) {
+    skipBuild("C++11 support is required in order to build chromium.")
+    return(false)
+  }
+  qtConfig(mirclient) {
+    skipBuild("Mir is not yet supported as graphics backend for Qt WebEngine.")
+    return(false)
+  }
+  static {
+    skipBuild("Static builds of QtWebEngine aren't supported.")
+    return(false)
+  }
+  !isArchSupported(): return(false)
+  return(true)
+}
+
+defineTest(isArchSupported) {
+    contains(QT_ARCH, "i386")|contains(QT_ARCH, "x86_64"): return(true)
+    contains(QT_ARCH, "arm")|contains(QT_ARCH, "arm64"): return(true)
+    contains(QT_ARCH, "mips"): return(true)
+#     contains(QT_ARCH, "mips64"): return(true)
+
+    skipBuild("QtWebEngine can only be built for x86, x86-64, ARM, Aarch64, and MIPSel architectures.")
+    return(false)
+}
+
+defineTest(isGCCVersionSupported) {
+  # The below will work for gcc 4.7 and up and also match gcc 5
+  greaterThan(QT_GCC_MINOR_VERSION, 6):return(true)
+  greaterThan(QT_GCC_MAJOR_VERSION, 4):return(true)
+
+  skipBuild("Using gcc version "$$QT_GCC_MAJOR_VERSION"."$$QT_GCC_MINOR_VERSION", but at least gcc version 4.7 is required to build Qt WebEngine.")
+  return(false)
+}
+
+defineTest(isBuildingOnWin32) {
+    # The check below is ugly, but necessary, as it seems to be the only reliable way to detect if the host
+    # architecture is 32 bit. QMAKE_HOST.arch does not work as it returns the architecture that the toolchain
+    # is building for, not the system's actual architecture.
+    PROGRAM_FILES_X86 = $$(ProgramW6432)
+    isEmpty(PROGRAM_FILES_X86): return(true)
+    return(false)
+}
+
+defineTest(isMinOSXSDKVersion) {
+    requested_major = $$1
+    requested_minor = $$2
+    requested_patch = $$3
+    isEmpty(requested_patch): requested_patch = 0
+    WEBENGINE_OSX_SDK_PRODUCT_VERSION = $$system("/usr/bin/xcodebuild -sdk $$QMAKE_MAC_SDK -version ProductVersion 2>/dev/null")
+    export(WEBENGINE_OSX_SDK_PRODUCT_VERSION)
+    isEmpty(WEBENGINE_OSX_SDK_PRODUCT_VERSION) {
+        skipBuild("Could not resolve SDK product version for \'$$QMAKE_MAC_SDK\'.")
+        return(false)
+    }
+    major_version = $$section(WEBENGINE_OSX_SDK_PRODUCT_VERSION, ., 0, 0)
+    minor_version = $$section(WEBENGINE_OSX_SDK_PRODUCT_VERSION, ., 1, 1)
+    patch_version = $$section(WEBENGINE_OSX_SDK_PRODUCT_VERSION, ., 2, 2)
+    isEmpty(patch_version): patch_version = 0
+
+    greaterThan(major_version, $$requested_major):return(true)
+    equals(major_version, $$requested_major):greaterThan(minor_version, $$requested_minor):return(true)
+    equals(major_version, $$requested_major):equals(minor_version, $$requested_minor):!lessThan(patch_version, $$requested_patch):return(true)
+
+    return(false)
+}
+
+defineTest(isMinWinSDKVersion) {
+    requested_major = $$1
+    requested_minor = $$2
+    WIN_SDK_VERSION = $$(WindowsSDKVersion)
+
+    isEmpty(WIN_SDK_VERSION)|equals(WIN_SDK_VERSION, "\\") {
+        skipBuild("Could not detect Windows SDK version (\'WindowsSDKVersion\' environment variable is not set).")
+        return(false)
+    }
+
+    # major.0.minor
+    major_version = $$section(WIN_SDK_VERSION, ., 0, 0)
+    minor_version = $$section(WIN_SDK_VERSION, ., 2, 2)
+
+    greaterThan(major_version, $$requested_major):return(true)
+    equals(major_version, $$requested_major):greaterThan(minor_version, $$requested_minor):return(true)
+    equals(major_version, $$requested_major):equals(minor_version, $$requested_minor)::return(true)
+
+    return(false)
+}