1 files changed, 31 insertions, 0 deletions
diff --git a/tools/qmake/mkspecs/features/configure.prf b/tools/qmake/mkspecs/features/configure.prf
new file mode 100644
index 000000000..6e74b5547
--- /dev/null
+++ b/tools/qmake/mkspecs/features/configure.prf
@@ -0,0 +1,31 @@
+# Load configure.prf from qtbase first
+load(configure)
+load(functions)
+
+defineTest(runConfigure) {
+    webengine_successfully_configured: return(true)
+    linux:contains(QT_CONFIG,no-pkg-config) {
+        skipBuild("pkg-config is required")
+        return(false)
+    }
+    # Ignore the cached config tests results in case they were not successful
+    CONFIG += recheck
+    #Override the config.tests path
+    QMAKE_CONFIG_TESTS_DIR = $$QTWEBENGINE_ROOT/tools/qmake/config.tests
+    CONFIG_TESTS = $$files($$QMAKE_CONFIG_TESTS_DIR/*.pro, true)
+    log("Running configure tests$${EOL}")
+    for(test, CONFIG_TESTS) {
+        test = $$basename(test)
+        test ~= s/\\.pro$//
+        qtCompileTest($$test)
+    }
+    # libcap-dev package doesn't ship .pc files on Ubuntu.
+    linux:!config_libcap:skipBuild("libcap appears to be missing")
+    contains(QT_CONFIG, xcb) {
+        for(package, $$list("libdrm xcomposite xi xrandr")) {
+            !packagesExist($$package):skipBuild("Unmet dependency: $$package")
+        }
+    }
+    isEmpty(skipBuildReason):cache(CONFIG, add, $$list(webengine_successfully_configured))
+}
+