blob: c63602412c565e1db214a5460c66e85ae63c9c8a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
TEMPLATE = app
TARGET = browser
QT += webenginewidgets network widgets printsupport
macx: CONFIG -= app_bundle
qtHaveModule(uitools):!embedded: QT += uitools
else: DEFINES += QT_NO_UITOOLS
FORMS += \
addbookmarkdialog.ui \
bookmarks.ui \
cookies.ui \
cookiesexceptions.ui \
downloaditem.ui \
downloads.ui \
history.ui \
passworddialog.ui \
proxy.ui \
settings.ui
HEADERS += \
autosaver.h \
bookmarks.h \
browserapplication.h \
browsermainwindow.h \
chasewidget.h \
downloadmanager.h \
edittableview.h \
edittreeview.h \
history.h \
modelmenu.h \
searchlineedit.h \
settings.h \
squeezelabel.h \
tabwidget.h \
toolbarsearch.h \
urllineedit.h \
webview.h \
xbel.h
SOURCES += \
autosaver.cpp \
bookmarks.cpp \
browserapplication.cpp \
browsermainwindow.cpp \
chasewidget.cpp \
downloadmanager.cpp \
edittableview.cpp \
edittreeview.cpp \
history.cpp \
modelmenu.cpp \
searchlineedit.cpp \
settings.cpp \
squeezelabel.cpp \
tabwidget.cpp \
toolbarsearch.cpp \
urllineedit.cpp \
webview.cpp \
xbel.cpp \
main.cpp
RESOURCES += data/data.qrc htmls/htmls.qrc
contains(DEFINES, QWEBENGINEPAGE_SETNETWORKACCESSMANAGER) {
HEADERS += cookiejar.h networkaccessmanager.h
SOURCES += cookiejar.cpp networkaccessmanager.cpp
}
build_all:!build_pass {
CONFIG -= build_all
CONFIG += release
}
win32 {
RC_FILE = browser.rc
}
mac {
ICON = browser.icns
QMAKE_INFO_PLIST = Info_mac.plist
TARGET = Browser
# No 64-bit Flash on Mac, so build the browser 32-bit
contains(QT_CONFIG, x86) {
CONFIG -= x86_64
CONFIG += x86
}
contains(QT_CONFIG, ppc) {
CONFIG -= ppc64
CONFIG += ppc
}
}
wince*: {
DEPLOYMENT_PLUGIN += qjpeg qgif
}
EXAMPLE_FILES = Info_mac.plist browser.icns browser.ico browser.rc
# install
target.path = $$[QT_INSTALL_EXAMPLES]/webkitwidgets/browser
INSTALLS += target
|
