1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
|
/****************************************************************************
**
** Copyright (C) 2020 The Qt Company Ltd.
** Contact: http://www.qt.io/licensing/
**
** This file is part of the QtPDF module of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:LGPL3$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see http://www.qt.io/terms-conditions. For further
** information use the contact form at http://www.qt.io/contact-us.
**
** GNU Lesser General Public License Usage
** Alternatively, this file may be used under the terms of the GNU Lesser
** General Public License version 3 as published by the Free Software
** Foundation and appearing in the file LICENSE.LGPLv3 included in the
** packaging of this file. Please review the following information to
** ensure the GNU Lesser General Public License version 3 requirements
** will be met: https://www.gnu.org/licenses/lgpl.html.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 2.0 or later as published by the Free
** Software Foundation and appearing in the file LICENSE.GPL included in
** the packaging of this file. Please review the following information to
** ensure the GNU General Public License version 2.0 requirements will be
** met: http://www.gnu.org/licenses/gpl-2.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/
import QtQuick 2.15
import QtQuick.Controls 2.15
import QtQuick.Pdf 5.15
import QtQuick.Shapes 1.15
Rectangle {
id: paper
width: image.width
height: image.height
// public API
// TODO 5.15: required property
property var document: null
property real renderScale: 1
property alias sourceSize: image.sourceSize
property alias currentPage: image.currentFrame
property alias pageCount: image.frameCount
property alias searchString: searchModel.searchString
property alias selectedText: selection.text
property alias status: image.status
property real __pageScale: image.paintedWidth / document.pagePointSize(image.currentFrame).width
function resetScale() {
image.sourceSize.width = 0
image.sourceSize.height = 0
paper.x = 0
paper.y = 0
paper.scale = 1
}
function scaleToWidth(width, height) {
var halfRotation = Math.abs(paper.rotation % 180)
image.sourceSize = Qt.size((halfRotation > 45 && halfRotation < 135) ? height : width, 0)
paper.x = 0
paper.y = 0
image.centerInSize = Qt.size(width, height)
image.centerOnLoad = true
image.vCenterOnLoad = (halfRotation > 45 && halfRotation < 135)
paper.scale = 1
}
function scaleToPage(width, height) {
var windowAspect = width / height
var halfRotation = Math.abs(paper.rotation % 180)
var pagePointSize = document.pagePointSize(image.currentFrame)
if (halfRotation > 45 && halfRotation < 135) {
// rotated 90 or 270º
var pageAspect = pagePointSize.height / pagePointSize.width
if (windowAspect > pageAspect) {
image.sourceSize = Qt.size(height, 0)
} else {
image.sourceSize = Qt.size(0, width)
}
} else {
var pageAspect = pagePointSize.width / pagePointSize.height
if (windowAspect > pageAspect) {
image.sourceSize = Qt.size(0, height)
} else {
image.sourceSize = Qt.size(width, 0)
}
}
image.centerInSize = Qt.size(width, height)
image.centerOnLoad = true
image.vCenterOnLoad = true
paper.scale = 1
}
PdfSelection {
id: selection
document: paper.document
page: image.currentFrame
fromPoint: Qt.point(textSelectionDrag.centroid.pressPosition.x / paper.__pageScale, textSelectionDrag.centroid.pressPosition.y / paper.__pageScale)
toPoint: Qt.point(textSelectionDrag.centroid.position.x / paper.__pageScale, textSelectionDrag.centroid.position.y / paper.__pageScale)
hold: !textSelectionDrag.active && !tapHandler.pressed
}
function copySelectionToClipboard() {
selection.copyToClipboard()
}
PdfSearchModel {
id: searchModel
document: paper.document
page: image.currentFrame
}
Image {
id: image
source: document.status === PdfDocument.Ready ? document.source : ""
asynchronous: true
fillMode: Image.PreserveAspectFit
property bool centerOnLoad: false
property bool vCenterOnLoad: false
property size centerInSize
onStatusChanged:
if (status == Image.Ready && centerOnLoad) {
paper.x = (centerInSize.width - image.implicitWidth) / 2
paper.y = vCenterOnLoad ? (centerInSize.height - image.implicitHeight) / 2 : 0
centerOnLoad = false
vCenterOnLoad = false
}
}
function reRenderIfNecessary() {
var newSourceWidth = image.sourceSize.width * paper.scale
var ratio = newSourceWidth / image.sourceSize.width
if (ratio > 1.1 || ratio < 0.9) {
image.sourceSize.width = newSourceWidth
image.sourceSize.height = 0
paper.scale = 1
}
}
onRenderScaleChanged: {
image.sourceSize.width = document.pagePointSize(image.currentFrame).width * renderScale
image.sourceSize.height = 0
paper.scale = 1
}
Shape {
anchors.fill: parent
opacity: 0.25
visible: image.status === Image.Ready
ShapePath {
strokeWidth: 1
strokeColor: "blue"
fillColor: "cyan"
scale: Qt.size(paper.__pageScale, paper.__pageScale)
PathMultiline {
id: searchResultBoundaries
paths: searchModel.matchGeometry
}
}
ShapePath {
fillColor: "orange"
scale: Qt.size(paper.__pageScale, paper.__pageScale)
PathMultiline {
id: selectionBoundaries
paths: selection.geometry
}
}
}
Repeater {
model: PdfLinkModel {
id: linkModel
document: paper.document
page: image.currentFrame
}
delegate: Rectangle {
color: "transparent"
border.color: "lightgrey"
x: rect.x * paper.__pageScale
y: rect.y * paper.__pageScale
width: rect.width * paper.__pageScale
height: rect.height * paper.__pageScale
HoverHandler { cursorShape: Qt.PointingHandCursor } // 5.15 onward (QTBUG-68073)
TapHandler {
onTapped: {
if (page >= 0)
image.currentFrame = page
else
Qt.openUrlExternally(url)
}
}
}
}
PinchHandler {
id: pinch
minimumScale: 0.1
maximumScale: 10
minimumRotation: 0
maximumRotation: 0
onActiveChanged: if (!active) paper.reRenderIfNecessary()
grabPermissions: PinchHandler.TakeOverForbidden // don't allow takeover if pinch has started
}
DragHandler {
id: pageMovingTouchDrag
acceptedDevices: PointerDevice.TouchScreen
}
DragHandler {
id: pageMovingMiddleMouseDrag
acceptedDevices: PointerDevice.Mouse | PointerDevice.Stylus
acceptedButtons: Qt.MiddleButton
snapMode: DragHandler.NoSnap
}
DragHandler {
id: textSelectionDrag
acceptedDevices: PointerDevice.Mouse | PointerDevice.Stylus
target: null
}
TapHandler {
id: tapHandler
acceptedDevices: PointerDevice.Mouse | PointerDevice.Stylus
}
}
|