blob: eab11189eba66c74687442958416bb1e5e7e02e0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
TARGET = $$QTWEBENGINEPROCESS_NAME
TEMPLATE = app
!build_pass:contains(QT_CONFIG, debug_and_release):contains(QT_CONFIG, build_all): CONFIG += release
# Needed to set LSUIElement=1
QMAKE_INFO_PLIST = Info_mac.plist
load(qt_build_paths)
contains(QT_CONFIG, qt_framework) {
# Deploy the QtWebEngineProcess app bundle into the QtWebEngineCore framework.
DESTDIR = $$MODULE_BASE_OUTDIR/lib/QtWebEngineCore.framework/Versions/5/Helpers
QT += webenginecore
QMAKE_RPATHDIR += @loader_path/../../../../../../../../Frameworks
} else {
CONFIG -= app_bundle
win32: DESTDIR = $$MODULE_BASE_OUTDIR/bin
else: DESTDIR = $$MODULE_BASE_OUTDIR/libexec
QT_PRIVATE += webenginecore
}
msvc: QMAKE_LFLAGS *= /LARGEADDRESSAWARE
INCLUDEPATH += ../core
SOURCES = main.cpp
win32 {
SOURCES += \
support_win.cpp
}
contains(QT_CONFIG, qt_framework) {
target.path = $$[QT_INSTALL_LIBS]/QtWebEngineCore.framework/Versions/5/Helpers
} else {
target.path = $$[QT_INSTALL_LIBEXECS]
}
INSTALLS += target
|