src/src.pro


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30

TEMPLATE = subdirs

isPlatformSupported() {
    process.depends = core
    webengine.depends = core
    webenginewidgets.depends = core webengine
    webengine_plugin.subdir = webengine/plugin
    webengine_plugin.target = sub-webengine-plugin
    webengine_plugin.depends = webengine
    webengine_experimental_plugin.subdir = webengine/plugin/experimental
    webengine_experimental_plugin.target = sub-webengine-experimental-plugin
    webengine_experimental_plugin.depends = webengine


    SUBDIRS += core \
               process \
               webengine \
               webengine_plugin \
               webengine_experimental_plugin

    # FIXME: We probably want a bit more control over config options to tweak what to build/ship or not.
    # Another example of where this could be necessary is to make it easy to build proprietery codecs support.
    !contains(WEBENGINE_CONFIG, no_ui_delegates): SUBDIRS += webengine/ui

    qtHaveModule(widgets) {
        SUBDIRS += webenginewidgets
    }
} else {
    warning("QtWebEngine is not maintained for this platform/configuration and is therefore disabled.")
}