blob: 3338e0cf7a6628fff069d2fa6a9ba4829f7b7b6e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Use Qt5 module system
load(qt_build_config)
TEMPLATE = lib
TARGET = QtWebEngineWidgets
MODULE = webenginewidgets
# For our export macros
DEFINES += QT_BUILD_WEBENGINEWIDGETS_LIB
QT += widgets
QT_PRIVATE += widgets-private gui-private core-private
# FIXME: all this should eventually be turned into QT += webenginecore
macx:LIBPATH = $$getOutDir()/$$getConfigDir()
else:LIBPATH = $$getOutDir()/$$getConfigDir()/lib
LIBS_PRIVATE += -lQt5WebEngineCore -L$$LIBPATH
QMAKE_RPATHDIR += $$LIBPATH
DESTDIR = $$LIBPATH
INCLUDEPATH += Api ../
SOURCES = \
Api/qwebenginehistory.cpp \
Api/qwebenginepage.cpp \
Api/qwebengineview.cpp\
render_widget_host_view_qt_delegate_widget.cpp
HEADERS = \
Api/qtwebenginewidgetsglobal.h \
Api/qwebenginehistory.h \
Api/qwebenginepage.h \
Api/qwebengineview.h \
Api/qwebengineview_p.h \
render_widget_host_view_qt_delegate_widget.h
load(qt_module)
# QNX ld only supports staging-relative rpath values and can't use the rpath specified above.
# Instead, append an appropriate rpath-link to lib_qt_webenginewidgets.pri.
qnx:!build_pass {
local_build_rpath_link = "QMAKE_RPATHLINKDIR += $$LIBPATH"
# MODULE_PRI is defined in qt_module_pris.prf
write_file($$MODULE_PRI, local_build_rpath_link, append)
}
|