blob: 61aa621a7696025652a80c83d46e63310e454d4e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Use Qt5 module system
load(qt_build_config)
TEMPLATE = lib
TARGET = QtWebEngineWidgets
MODULE = webenginewidgets
# For our export macros
DEFINES += QT_BUILD_WEBENGINEWIDGETS_LIB
QT += widgets
QT_PRIVATE += widgets-private gui-private core-private
# FIXME: all this should eventually be turned into QT += webenginecore
macx:LIBPATH = $$getOutDir()/$$getConfigDir()
else:LIBPATH = $$getOutDir()/$$getConfigDir()/lib
LIBS_PRIVATE += -L$$LIBPATH -lQt5WebEngineCore
QMAKE_RPATHDIR += $$LIBPATH
DESTDIR = $$LIBPATH
INCLUDEPATH += api ../core
SOURCES = \
api/qwebenginehistory.cpp \
api/qwebenginepage.cpp \
api/qwebengineview.cpp\
render_widget_host_view_qt_delegate_popup.cpp \
render_widget_host_view_qt_delegate_webpage.cpp
HEADERS = \
api/qtwebenginewidgetsglobal.h \
api/qwebenginehistory.h \
api/qwebenginepage.h \
api/qwebengineview.h \
api/qwebengineview_p.h \
render_widget_host_view_qt_delegate_popup.h \
render_widget_host_view_qt_delegate_webpage.h
load(qt_module)
# Some binutils versions configured for cross compilation only support
# sysroot-relative rpath values and can't use the rpath specified above.
# Instead, append an appropriate rpath-link to lib_qt_webenginewidgets.pri.
cross_compile:!build_pass {
local_build_rpath_link = "QMAKE_RPATHLINKDIR += $$LIBPATH"
# MODULE_PRI is defined in qt_module_pris.prf
write_file($$MODULE_PRI, local_build_rpath_link, append)
}
|