blob: ffbef84d92d50d9c918fac32d6b2d51a2d1f6fb2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Load configure.prf from qtbase first
load(configure)
load(functions)
defineTest(runConfigure) {
webengine_successfully_configured: return(true)
linux:contains(QT_CONFIG,no-pkg-config) {
skipBuild("pkg-config is required")
return(false)
}
# Ignore the cached config tests results in case they were not successful
CONFIG += recheck
#Override the config.tests path
QMAKE_CONFIG_TESTS_DIR = $$QTWEBENGINE_ROOT/tools/qmake/config.tests
CONFIG_TESTS = $$files($$QMAKE_CONFIG_TESTS_DIR/*.pro, true)
log("Running configure tests$${EOL}")
for(test, CONFIG_TESTS) {
test = $$basename(test)
test ~= s/\\.pro$//
qtCompileTest($$test)
}
# libcap-dev package doesn't ship .pc files on Ubuntu.
linux:!config_libcap:skipBuild("libcap development package appears to be missing")
linux:!config_khr:skipBuild("khronos development headers appear to be missing (mesa/libegl1-mesa-dev)")
contains(QT_CONFIG, xcb) {
for(package, $$list("libdrm xcomposite xi xrandr")) {
!packagesExist($$package):skipBuild("Unmet dependency: $$package")
}
}
linux {
packagesExist(minizip, zlib): CONFIG += config_system_minizip
else: log("System zlib and minizip not found. Using Chromium's copies.$${EOL}")
packagesExist(libxml-2.0,libxslt): CONFIG += config_system_libxslt
else: log("System libxml2 and libxslt not found. Using Chromium's copies.$${EOL}")
}
isEmpty(skipBuildReason):cache(CONFIG, add, $$list(webengine_successfully_configured))
}
|