blob: 61648331b8cfd5fb70af5b357333b2eba4725aa3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
|
# Automoc
set(TARGETS_WITH_AUTOMOC
WebKit
WebKitWidgets
)
if (ENABLE_WEBKIT2)
list(APPEND TARGETS_WITH_AUTOMOC
WebKit2
)
endif ()
set_property(TARGET ${TARGETS_WITH_AUTOMOC} PROPERTY AUTOMOC ON)
# Minimal debug
# Builds with debug flags result in a huge amount of symbols with the GNU toolchain,
# resulting in the need of several gigabytes of memory at link-time. Reduce the pressure
# by compiling any static library like WTF or JSC with optimization flags instead and keep
# debug symbols for the static libraries that implement API.
cmake_dependent_option(USE_MINIMAL_DEBUG_INFO "Add debug info only for the libraries that implement API" OFF
"NOT MINGW;NOT APPLE" ON)
if (USE_MINIMAL_DEBUG_INFO AND CMAKE_BUILD_TYPE STREQUAL "Debug")
target_compile_options(WTF PRIVATE -g0 -O1)
target_compile_options(JavaScriptCore PRIVATE -g0 -O1)
target_compile_options(WebCore PRIVATE -g0 -O1)
target_compile_options(WebCoreTestSupport PRIVATE -g0 -O1)
if (TARGET ANGLESupport)
target_compile_options(ANGLESupport PRIVATE -g0 -O1)
endif ()
if (TARGET gtest)
target_compile_options(gtest PRIVATE -g0 -O1)
endif ()
target_compile_options(WebKit PRIVATE -g1 -O1)
target_compile_options(WebKit2 PRIVATE -g1 -O1)
if (NOT APPLE)
target_compile_options(WebKit PRIVATE -fdebug-types-section)
target_compile_options(WebKit2 PRIVATE -fdebug-types-section)
endif ()
endif ()
if (USE_MINIMAL_DEBUG_INFO_MSVC AND MSVC AND CMAKE_BUILD_TYPE STREQUAL "Debug")
set(CMAKE_C_FLAGS_DEBUG ${CMAKE_C_FLAGS_RELEASE})
set(CMAKE_CXX_FLAGS_DEBUG ${CMAKE_CXX_FLAGS_RELEASE})
target_compile_options(WebKit PRIVATE /Zi)
if (TARGET WebKit2)
target_compile_options(WebKit2 PRIVATE /Zi)
endif ()
if (TARGET WebKitWidgets)
target_compile_options(WebKitWidgets PRIVATE /Zi)
endif ()
endif ()
# GTest
if (TARGET gtest)
set(GTEST_DEFINITIONS QT_NO_KEYWORDS)
if (COMPILER_IS_GCC_OR_CLANG)
list(APPEND GTEST_DEFINITIONS "GTEST_API_=__attribute__((visibility(\"default\")))")
endif ()
set_target_properties(gtest PROPERTIES COMPILE_DEFINITIONS "${GTEST_DEFINITIONS}")
endif ()
# Installation
target_compile_definitions(WebKit INTERFACE QT_WEBKIT_LIB)
target_include_directories(WebKit INTERFACE
$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>
$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/QtWebKit>
)
target_compile_definitions(WebKitWidgets INTERFACE QT_WEBKITWIDGETS_LIB)
target_include_directories(WebKitWidgets INTERFACE
$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}>
$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR}/QtWebKitWidgets>
)
set(QTWEBKIT_PACKAGE_INIT "
macro(find_dependency_with_major_and_minor _dep _major _minor)
find_dependency(\${_dep} \"\${_major}.\${_minor}\")
if (NOT(\"\${\${_dep}_VERSION_MAJOR}\" STREQUAL \"\${_major}\" AND \"\${\${_dep}_VERSION_MINOR}\" STREQUAL \"\${_minor}\"))
set(\${CMAKE_FIND_PACKAGE_NAME}_NOT_FOUND_MESSAGE \"\${CMAKE_FIND_PACKAGE_NAME} could not be found because dependency \${dep} is required to have exact version \${_major}.\${_minor}.x.\")
set(\${CMAKE_FIND_PACKAGE_NAME}_FOUND False)
return()
endif ()
endmacro ()
####################################################################################
")
set(_package_footer_template "
####### Expanded from QTWEBKIT_PACKAGE_FOOTER variable #######
set(Qt5@MODULE_NAME@_LIBRARIES Qt5::@MODULE_NAME@)
set(Qt5@MODULE_NAME@_VERSION_STRING \${Qt5@MODULE_NAME@_VERSION})
set(Qt5@MODULE_NAME@_EXECUTABLE_COMPILE_FLAGS \"\")
set(Qt5@MODULE_NAME@_PRIVATE_INCLUDE_DIRS \"\") # FIXME: Support private headers
get_target_property(Qt5@MODULE_NAME@_INCLUDE_DIRS Qt5::@MODULE_NAME@ INTERFACE_INCLUDE_DIRECTORIES)
get_target_property(Qt5@MODULE_NAME@_COMPILE_DEFINITIONS Qt5::@MODULE_NAME@ INTERFACE_COMPILE_DEFINITIONS)
foreach (_module_dep \${_Qt5@MODULE_NAME@_MODULE_DEPENDENCIES})
list(APPEND Qt5@MODULE_NAME@_INCLUDE_DIRS \${Qt5\${_module_dep}_INCLUDE_DIRS})
list(APPEND Qt5@MODULE_NAME@_PRIVATE_INCLUDE_DIRS \${Qt5\${_module_dep}_PRIVATE_INCLUDE_DIRS})
list(APPEND Qt5@MODULE_NAME@_DEFINITIONS \${Qt5\${_module_dep}_DEFINITIONS})
list(APPEND Qt5@MODULE_NAME@_COMPILE_DEFINITIONS \${Qt5\${_module_dep}_COMPILE_DEFINITIONS})
list(APPEND Qt5@MODULE_NAME@_EXECUTABLE_COMPILE_FLAGS \${Qt5\${_module_dep}_EXECUTABLE_COMPILE_FLAGS})
endforeach ()
list(REMOVE_DUPLICATES Qt5@MODULE_NAME@_INCLUDE_DIRS)
list(REMOVE_DUPLICATES Qt5@MODULE_NAME@_PRIVATE_INCLUDE_DIRS)
list(REMOVE_DUPLICATES Qt5@MODULE_NAME@_DEFINITIONS)
list(REMOVE_DUPLICATES Qt5@MODULE_NAME@_COMPILE_DEFINITIONS)
list(REMOVE_DUPLICATES Qt5@MODULE_NAME@_EXECUTABLE_COMPILE_FLAGS)
")
set(MODULE_NAME WebKit)
string(CONFIGURE ${_package_footer_template} QTWEBKIT_PACKAGE_FOOTER @ONLY)
ecm_configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/Qt5WebKitConfig.cmake.in"
"${CMAKE_CURRENT_BINARY_DIR}/Qt5WebKitConfig.cmake"
INSTALL_DESTINATION "${KDE_INSTALL_CMAKEPACKAGEDIR}/Qt5WebKit"
)
set(MODULE_NAME WebKitWidgets)
string(CONFIGURE ${_package_footer_template} QTWEBKIT_PACKAGE_FOOTER @ONLY)
ecm_configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/Qt5WebKitWidgetsConfig.cmake.in"
"${CMAKE_CURRENT_BINARY_DIR}/Qt5WebKitWidgetsConfig.cmake"
INSTALL_DESTINATION "${KDE_INSTALL_CMAKEPACKAGEDIR}/Qt5WebKitWidgets"
)
unset(MODULE_NAME)
unset(QTWEBKIT_PACKAGE_FOOTER)
write_basic_package_version_file("${CMAKE_CURRENT_BINARY_DIR}/Qt5WebKitConfigVersion.cmake"
VERSION ${PROJECT_VERSION}
COMPATIBILITY AnyNewerVersion)
write_basic_package_version_file("${CMAKE_CURRENT_BINARY_DIR}/Qt5WebKitWidgetsConfigVersion.cmake"
VERSION ${PROJECT_VERSION}
COMPATIBILITY AnyNewerVersion)
install(FILES
"${CMAKE_CURRENT_BINARY_DIR}/Qt5WebKitConfig.cmake"
"${CMAKE_CURRENT_BINARY_DIR}/Qt5WebKitConfigVersion.cmake"
DESTINATION "${KDE_INSTALL_CMAKEPACKAGEDIR}/Qt5WebKit"
COMPONENT Data
)
install(FILES
"${CMAKE_CURRENT_BINARY_DIR}/Qt5WebKitWidgetsConfig.cmake"
"${CMAKE_CURRENT_BINARY_DIR}/Qt5WebKitWidgetsConfigVersion.cmake"
DESTINATION "${KDE_INSTALL_CMAKEPACKAGEDIR}/Qt5WebKitWidgets"
COMPONENT Data
)
install(EXPORT WebKitTargets
FILE WebKitTargets.cmake
NAMESPACE Qt5::
DESTINATION "${KDE_INSTALL_CMAKEPACKAGEDIR}/Qt5WebKit"
COMPONENT Data
)
install(EXPORT Qt5WebKitWidgetsTargets
FILE Qt5WebKitWidgetsTargets.cmake
NAMESPACE Qt5::
DESTINATION "${KDE_INSTALL_CMAKEPACKAGEDIR}/Qt5WebKitWidgets"
COMPONENT Data
)
# Documentation
if (NOT TARGET Qt5::qdoc)
add_executable(Qt5::qdoc IMPORTED)
query_qmake(QDOC_EXECUTABLE QT_INSTALL_BINS)
set(QDOC_EXECUTABLE "${QDOC_EXECUTABLE}/qdoc")
set_target_properties(Qt5::qdoc PROPERTIES
IMPORTED_LOCATION ${QDOC_EXECUTABLE}
)
endif ()
if (NOT TARGET Qt5::qhelpgenerator)
add_executable(Qt5::qhelpgenerator IMPORTED)
query_qmake(QHELPGENERATOR_EXECUTABLE QT_INSTALL_BINS)
set(QHELPGENERATOR_EXECUTABLE "${QHELPGENERATOR_EXECUTABLE}/qhelpgenerator")
set_target_properties(Qt5::qhelpgenerator PROPERTIES
IMPORTED_LOCATION ${QHELPGENERATOR_EXECUTABLE}
)
endif ()
query_qmake(QT_INSTALL_DOCS QT_INSTALL_DOCS)
set(QDOC_CONFIG "${CMAKE_SOURCE_DIR}/Source/qtwebkit.qdocconf")
set(DOC_OUTPUT_DIR "${CMAKE_BINARY_DIR}/doc")
set(PROJECT_VERSION_TAG ${PROJECT_VERSION_MAJOR}${PROJECT_VERSION_MINOR}${PROJECT_VERSION_PATCH})
if (KDE_INSTALL_USE_QT_SYS_PATHS)
set(DOC_INSTALL_DIR ${QT_INSTALL_DOCS})
else ()
set(DOC_INSTALL_DIR "doc")
endif ()
if (WIN32)
set(EXPORT_VAR set)
else ()
set(EXPORT_VAR export)
endif ()
if (GENERATE_DOCUMENTATION)
set(NEED_ALL "ALL")
else ()
set(NEED_ALL "")
endif ()
set(EXPORT_VARS_COMMANDS
COMMAND ${EXPORT_VAR} "QT_INSTALL_DOCS=${QT_INSTALL_DOCS}"
COMMAND ${EXPORT_VAR} "QT_VER=${PROJECT_VERSION_STRING}"
COMMAND ${EXPORT_VAR} "QT_VERSION=${PROJECT_VERSION_STRING}"
COMMAND ${EXPORT_VAR} "QT_VERSION_TAG=${PROJECT_VERSION_TAG}"
)
add_custom_target(prepare_docs ${NEED_ALL}
${EXPORT_VARS_COMMANDS}
COMMAND Qt5::qdoc ${QDOC_CONFIG} -prepare -outputdir "${DOC_OUTPUT_DIR}/qtwebkit" -installdir ${DOC_INSTALL_DIR} -indexdir ${QT_INSTALL_DOCS} -no-link-errors
VERBATIM
)
add_custom_target(generate_docs ${NEED_ALL}
${EXPORT_VARS_COMMANDS}
COMMAND Qt5::qdoc ${QDOC_CONFIG} -generate -outputdir "${DOC_OUTPUT_DIR}/qtwebkit" -installdir ${DOC_INSTALL_DIR} -indexdir ${QT_INSTALL_DOCS}
VERBATIM
)
add_dependencies(generate_docs prepare_docs)
add_custom_target(html_docs)
add_dependencies(html_docs generate_docs)
add_custom_target(qch_docs ${NEED_ALL}
COMMAND Qt5::qhelpgenerator "${DOC_OUTPUT_DIR}/qtwebkit/qtwebkit.qhp" -o "${DOC_OUTPUT_DIR}/qtwebkit.qch"
VERBATIM
)
add_dependencies(qch_docs html_docs)
add_custom_target(docs)
add_dependencies(docs qch_docs)
if (GENERATE_DOCUMENTATION)
install(DIRECTORY "${DOC_OUTPUT_DIR}/qtwebkit" DESTINATION ${DOC_INSTALL_DIR} COMPONENT Data)
install(FILES "${DOC_OUTPUT_DIR}/qtwebkit.qch" DESTINATION ${DOC_INSTALL_DIR} COMPONENT Data)
endif ()
# Uninstall target
configure_file(
"${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
"${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
IMMEDIATE @ONLY
)
add_custom_target(uninstall
COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake
)
|
