summaryrefslogtreecommitdiffstats
path: root/src/imports/StudioControls/Slider.qml
blob: e8cfe2a13a94cf9c128f5a9dead14ff427695aa3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
/****************************************************************************
**
** Copyright (C) 2019 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of Qt Creator.
**
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 as published by the Free Software
** Foundation with exceptions as appearing in the file LICENSE.GPL3-EXCEPT
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
****************************************************************************/

import QtQuick 2.12
import QtQuick.Shapes 1.12
import QtQuick.Templates 2.12 as T
import StudioTheme 1.0 as StudioTheme

T.Slider {
    id: slider

    property int decimals: 0
    property bool labels: true
    property bool tickMarks: false
    property real tickMarkStepSize: 0.0 // StepSize bug QTBUG-76136
    property real tickMarkWidth: 1.0
    property real tickMarkHeight: 4.0
    readonly property int tickMarkCount: tickMarkStepSize
                                         !== 0.0 ? (to - from) / tickMarkStepSize + 1 : 0
    readonly property real tickMarkSpacing: tickMarkCount
                                            !== 0 ? (sliderTrack.width - tickMarkWidth
                                                     * tickMarkCount) / (tickMarkCount - 1) : 0.0

    property string __activeColor: StudioTheme.Values.themeSliderActiveTrack
    property string __inactiveColor: StudioTheme.Values.themeSliderInactiveTrack

    property bool hover: false // This property is used to indicate the global hover state
    property bool edit: slider.activeFocus

    property alias actionIndicatorVisible: actionIndicator.visible
    property real __actionIndicatorWidth: StudioTheme.Values.squareComponentWidth
    property real __actionIndicatorHeight: StudioTheme.Values.height

    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
                            implicitHandleWidth + leftPadding + rightPadding)
    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
                             implicitHandleHeight + topPadding + bottomPadding,
                             StudioTheme.Values.height)
    padding: 0
    leftPadding: actionIndicator.width
                 - (actionIndicatorVisible ? StudioTheme.Values.border
                                             - StudioTheme.Values.sliderPadding : 0)

    wheelEnabled: false

    ActionIndicator {
        id: actionIndicator
        myControl: slider
        x: 0
        y: 0
        width: actionIndicator.visible ? __actionIndicatorWidth : 0
        height: actionIndicator.visible ? __actionIndicatorHeight : 0
    }

    handle: Rectangle {
        id: sliderHandle
        x: slider.leftPadding + (slider.visualPosition * slider.availableWidth)
           - (sliderHandle.width / 2)
        y: slider.topPadding + (slider.availableHeight / 2) - (sliderHandle.height / 2)
        z: 20
        implicitWidth: StudioTheme.Values.sliderHandleWidth
        implicitHeight: StudioTheme.Values.sliderHandleHeight
        color: StudioTheme.Values.themeSliderHandle

        Shape {
            id: sliderHandleLabelPointer

            property real __width: StudioTheme.Values.sliderPointerWidth
            property real __height: StudioTheme.Values.sliderPointerHeight
            property bool antiAlias: true

            layer.enabled: antiAlias
            layer.smooth: antiAlias
            layer.textureSize: Qt.size(width * 2, height * 2)

            implicitWidth: __width
            implicitHeight: __height

            anchors.horizontalCenter: parent.horizontalCenter
            anchors.top: sliderHandleLabelBackground.bottom

            ShapePath {
                id: sliderHandleLabelPointerPath
                strokeColor: "transparent"
                strokeWidth: 0
                fillColor: StudioTheme.Values.themeInteraction

                startX: 0
                startY: 0

                PathLine {
                    x: sliderHandleLabelPointer.__width
                    y: 0
                }
                PathLine {
                    x: sliderHandleLabelPointer.__width / 2
                    y: sliderHandleLabelPointer.__height
                }
            }
        }

        Rectangle {
            id: sliderHandleLabelBackground
            x: -(sliderHandleLabelBackground.width / 2) + (sliderHandle.width / 2)
            width: makeEven(
                       sliderHandleLabel.width + StudioTheme.Values.inputHorizontalPadding)
            height: sliderHandleLabel.height
            anchors.bottom: parent.top
            anchors.bottomMargin: StudioTheme.Values.sliderMargin
            color: StudioTheme.Values.themeInteraction

            Text {
                id: sliderHandleLabel
                anchors.horizontalCenter: parent.horizontalCenter
                anchors.verticalCenter: parent.verticalCenter
                text: Number.parseFloat(slider.value).toFixed(slider.decimals)
                color: StudioTheme.Values.themeTextColor
                font.pixelSize: StudioTheme.Values.sliderFontSize
            }
        }
    }

    function makeEven(value) {
        var v = Math.round(value)
        return (v % 2 === 0) ? v : v + 1
    }

    background: Rectangle {
        id: sliderTrack
        x: slider.leftPadding
        y: slider.topPadding + slider.availableHeight / 2 - height / 2
        width: slider.availableWidth
        height: StudioTheme.Values.sliderTrackHeight
        color: __inactiveColor

        Rectangle {
            width: slider.visualPosition * parent.width
            height: parent.height
            color: __activeColor
        }
    }

    Item {
        id: tickmarkBounds
        x: sliderTrack.x
        y: sliderTrack.y

        Text {
            id: tickmarkFromLabel
            x: 0
            y: StudioTheme.Values.sliderPadding
            text: Number.parseFloat(slider.from).toFixed(slider.decimals)
            color: StudioTheme.Values.themeTextColor
            font.pixelSize: StudioTheme.Values.sliderFontSize
            visible: slider.labels
        }

        Text {
            id: tickmarkToLabel
            x: slider.availableWidth - width
            y: StudioTheme.Values.sliderPadding
            text: Number.parseFloat(slider.to).toFixed(slider.decimals)
            color: StudioTheme.Values.themeTextColor
            font.pixelSize: StudioTheme.Values.sliderFontSize
            visible: slider.labels
        }

        Row {
            id: tickmarkRow
            spacing: tickMarkSpacing
            visible: slider.tickMarks

            Repeater {
                id: tickmarkRepeater
                model: tickMarkCount
                delegate: Rectangle {
                    implicitWidth: tickMarkWidth
                    implicitHeight: StudioTheme.Values.sliderTrackHeight
                    color: x < (slider.visualPosition
                                * slider.availableWidth) ? __inactiveColor : __activeColor
                }
            }
        }
    }

    MouseArea {
        id: mouseArea
        x: actionIndicator.width
        y: 0
        width: slider.width - actionIndicator.width
        height: slider.height
        enabled: true
        hoverEnabled: true
        propagateComposedEvents: true
        acceptedButtons: Qt.LeftButton
        cursorShape: Qt.PointingHandCursor
        // Sets the global hover
        onContainsMouseChanged: slider.hover = containsMouse
        onPressed: mouse.accepted = false
    }

    states: [
        State {
            name: "default"
            when: slider.enabled && !slider.hover && !slider.edit
            PropertyChanges {
                target: slider
                wheelEnabled: false
            }
        },
        State {
            name: "hovered"
            when: slider.enabled && slider.hover && !slider.edit
            PropertyChanges {
                target: slider
                __activeColor: StudioTheme.Values.themeSliderActiveTrackHover
                __inactiveColor: StudioTheme.Values.themeSliderInactiveTrackHover
            }
            PropertyChanges {
                target: sliderHandle
                color: StudioTheme.Values.themeSliderHandleHover
            }
        },
        State {
            name: "focus"
            when: slider.enabled && slider.edit
            PropertyChanges {
                target: slider
                wheelEnabled: true
                __activeColor: StudioTheme.Values.themeSliderActiveTrackFocus
                __inactiveColor: StudioTheme.Values.themeSliderInactiveTrackFocus
            }
            PropertyChanges {
                target: sliderHandle
                color: StudioTheme.Values.themeSliderHandleFocus
            }
        },
        State {
            name: "disabled"
            when: !slider.enabled
            PropertyChanges {
                target: tickmarkFromLabel
                color: StudioTheme.Values.themeTextColorDisabled
            }
            PropertyChanges {
                target: tickmarkToLabel
                color: StudioTheme.Values.themeTextColorDisabled
            }
            PropertyChanges {
                target: sliderHandleLabel
                color: StudioTheme.Values.themeTextColorDisabled
            }
            PropertyChanges {
                target: slider
                __activeColor: StudioTheme.Values.themeControlBackgroundDisabled
                __inactiveColor: StudioTheme.Values.themeControlBackgroundDisabled
            }
            PropertyChanges {
                target: sliderHandleLabelBackground
                color: StudioTheme.Values.themeControlBackgroundDisabled
            }
            PropertyChanges {
                target: sliderHandleLabelPointerPath
                fillColor: StudioTheme.Values.themeControlBackgroundDisabled
            }
            PropertyChanges {
                target: sliderHandle
                color: StudioTheme.Values.themeControlBackgroundDisabled
            }
        }
    ]
}