4 files changed, 117 insertions, 67 deletions
diff --git a/recipes-python/pyqt5/python3-pyqt-builder-native_1.15.0.bb b/recipes-python/pyqt5/python3-pyqt-builder-native_1.15.0.bb
new file mode 100644
index 00000000..7f16eb7b
--- /dev/null
+++ b/recipes-python/pyqt5/python3-pyqt-builder-native_1.15.0.bb
@@ -0,0 +1,10 @@
+SUMMARY = "The PEP 517 compliant PyQt build system"
+HOMEPAGE = "https://pypi.org/project/PyQt-builder/"
+LICENSE = "SIP | GPL-2.0-or-later"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=9cd437778ebd1c056a76b4ded73b3a6d"
+
+SRC_URI[sha256sum] = "a90553703897eb41e27c2f1abd31fb9ed304c32ec3271b380015b54ea9762ddd"
+
+inherit pypi setuptools3 native
+
+PYPI_PACKAGE = "PyQt-builder"
diff --git a/recipes-python/pyqt5/python3-pyqt5-sip_12.12.1.bb b/recipes-python/pyqt5/python3-pyqt5-sip_12.12.1.bb
new file mode 100644
index 00000000..a776324e
--- /dev/null
+++ b/recipes-python/pyqt5/python3-pyqt5-sip_12.12.1.bb
@@ -0,0 +1,10 @@
+SUMMARY = "The sip module support for PyQt5"
+HOMEPAGE = "https://pypi.org/project/PyQt5-sip/"
+LICENSE = "SIP | GPL-2.0-or-later"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=9cd437778ebd1c056a76b4ded73b3a6d"
+
+SRC_URI[sha256sum] = "8fdc6e0148abd12d977a1d3828e7b79aae958e83c6cb5adae614916d888a6b10"
+
+inherit pypi setuptools3
+
+PYPI_PACKAGE = "PyQt5_sip"
diff --git a/recipes-python/pyqt5/python3-pyqt5_5.15.1.bb b/recipes-python/pyqt5/python3-pyqt5_5.15.1.bb
deleted file mode 100644
index b751268d..00000000
--- a/recipes-python/pyqt5/python3-pyqt5_5.15.1.bb
+++ /dev/null
@@ -1,67 +0,0 @@
-SUMMARY = "Python Qt5 Bindings"
-AUTHOR = "Phil Thomson @ riverbank.co.uk"
-HOMEPAGE = "https://www.riverbankcomputing.com/software/pyqt"
-SECTION = "devel/python"
-LICENSE = "GPL-3.0-only"
-LIC_FILES_CHKSUM = "\
-    file://LICENSE;md5=d32239bcb673463ab874e80d47fae504 \
-"
-
-inherit pypi
-
-PYPI_PACKAGE = "PyQt5"
-
-SRC_URI[md5sum] = "b60f895e70d31d774e6cd374efd17c65"
-SRC_URI[sha256sum] = "d9a76b850246d08da9863189ecb98f6c2aa9b4d97a3e85e29330a264aed0f9a1"
-
-S = "${WORKDIR}/PyQt5-${PV}"
-
-inherit qmake5
-inherit python3native python3-dir
-
-DEPENDS = "qtbase qtdeclarative qtquickcontrols2"
-DEPENDS += "sip3 sip3-native python3"
-
-export BUILD_SYS
-export HOST_SYS
-export STAGING_INCDIR
-export STAGING_LIBDIR
-
-PARALLEL_MAKEINST = ""
-
-DISABLED_FEATURES = "PyQt_Desktop_OpenGL PyQt_Accessibility PyQt_SessionManager ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', '', 'PyQt_OpenGL', d)}"
-
-PYQT_MODULES = "QtCore QtGui QtNetwork QtXml QtNetwork QtQml ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'QtQuick QtWidgets QtQuickWidgets', '', d)}"
-
-do_configure:prepend() {
-    cd ${S}
-    echo "py_platform = linux" > pyqt.cfg
-    echo "py_inc_dir = %(sysroot)/$includedir/python%(py_major).%(py_minor)${PYTHON_ABI}" >> pyqt.cfg
-    echo "py_pylib_dir = %(sysroot)/${libdir}/python%(py_major).%(py_minor)" >> pyqt.cfg
-    echo "py_pylib_lib = python$%(py_major).%(py_minor)" >> pyqt.cfg
-    echo "pyqt_module_dir = ${D}/${libdir}/python%(py_major).%(py_minor)/site-packages" >> pyqt.cfg
-    echo "pyqt_bin_dir = ${D}/${bindir}" >> pyqt.cfg
-    echo "pyqt_sip_dir = ${D}/${datadir}/sip/PyQt5" >> pyqt.cfg
-    echo "pyuic_interpreter = ${D}/${bindir}/python%(py_major).%(py_minor)" >> pyqt.cfg
-    echo "pyqt_disabled_features = ${DISABLED_FEATURES}" >> pyqt.cfg
-    echo "qt_shared = True" >> pyqt.cfg
-    QT_VERSION=`${OE_QMAKE_QMAKE} -query QT_VERSION`
-    echo "[Qt $QT_VERSION]" >> pyqt.cfg
-    echo "pyqt_modules = ${PYQT_MODULES}" >> pyqt.cfg
-    echo yes | ${PYTHON} configure.py --verbose --qmake  ${STAGING_BINDIR_NATIVE}/${QT_DIR_NAME}/qmake --configuration pyqt.cfg --sysroot ${STAGING_DIR_HOST}
-}
-
-do_compile() {
-    cd ${S}
-    oe_runmake
-}
-
-do_install() {
-    cd ${S}
-    oe_runmake MAKEFLAGS='-j 1' install
-}
-
-FILES:${PN} += "${libdir}/${PYTHON_DIR}/site-packages ${datadir}/sip/PyQt5/"
-
-RDEPENDS:${PN} = "qtbase qtdeclarative qtquickcontrols2 qtquickcontrols2-mkspecs"
-RDEPENDS:${PN} += "python3-core python3-sip3"
diff --git a/recipes-python/pyqt5/python3-pyqt5_5.15.9.bb b/recipes-python/pyqt5/python3-pyqt5_5.15.9.bb
new file mode 100644
index 00000000..3361cd50
--- /dev/null
+++ b/recipes-python/pyqt5/python3-pyqt5_5.15.9.bb
@@ -0,0 +1,97 @@
+SUMMARY = "Python qt5 Bindings"
+HOMEPAGE = "https://www.riverbankcomputing.com/software/pyqt"
+SECTION = "devel/python"
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=d32239bcb673463ab874e80d47fae504"
+
+inherit pypi python3-dir python3native qmake5 qmake5_paths
+
+SRC_URI[sha256sum] = "dc41e8401a90dc3e2b692b411bd5492ab559ae27a27424eed4bd3915564ec4c0"
+PYPI_PACKAGE = "PyQt5"
+
+S = "${WORKDIR}/PyQt5-${PV}"
+
+DEPENDS = " \
+    python3 \
+    python3-ply-native \
+    python3-pyqt-builder-native \
+    python3-toml-native \
+    qtbase \
+    qtdeclarative \
+    qtquickcontrols2 \
+    sip \
+    sip-native \
+"
+
+DISABLED_FEATURES = " \
+    PyQt_Desktop_OpenGL \
+    PyQt_Accessibility \
+    PyQt_SessionManager \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', '', 'PyQt_OpenGL', d)} \
+"
+
+PYQT_MODULES = " \
+    QtCore \
+    QtGui \
+    QtNetwork \
+    QtXml \
+    QtNetwork \
+    QtQml \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'QtQuick QtWidgets QtQuickWidgets', '', d)} \
+"
+
+do_configure:prepend() {
+    local i
+    local extra_args
+
+    cd ${S}
+
+    for i in ${DISABLED_FEATURES}; do
+        extra_args="${extra_args} --disabled-feature=${i}"
+    done
+
+    for i in ${PYQT_MODULES}; do
+        extra_args="${extra_args} --enable=${i}"
+    done
+
+    sip-build \
+        --verbose \
+        --confirm-license \
+        --scripts-dir="${bindir}" \
+        --build-dir="${B}" \
+        --target-dir="${PYTHON_SITEPACKAGES_DIR}" \
+        --qmake=${OE_QMAKE_QMAKE} \
+        --no-make \
+        --enable=pylupdate \
+        --enable=pyrcc \
+        --enable=Qt \
+        --enable=QtCore \
+        --no-dbus-python \
+        ${extra_args}
+
+    QMAKE_PROFILES=${B}/PyQt5.pro
+}
+
+do_compile:append() {
+    sed -i "s,${STAGING_DIR_TARGET},," ${B}/inventory.txt
+}
+
+do_install:append() {
+    sed -i "s,exec .*nativepython3,exec ${bindir}/python3," ${D}/${bindir}/*
+}
+
+pyqt_fix_sources() {
+    find ${PKGD}/usr/src/debug/${PN} -type f -exec sed -i "s,\(${B}\|${S}\),/usr/src/debug/${PN}/${PV},g" {} \;
+}
+PACKAGESPLITFUNCS += "pyqt_fix_sources"
+
+FILES:${PN} += "${PYTHON_SITEPACKAGES_DIR} ${OE_QMAKE_PATH_PLUGINS}"
+RDEPENDS:${PN} = " \
+    python3-core \
+    python3-pyqt5-sip \
+    qtbase \
+    qtdeclarative  \
+    qtquickcontrols2 \
+    qtquickcontrols2-mkspecs \
+    sip \
+"