aboutsummaryrefslogtreecommitdiffstats
path: root/share/qtcreator/qmldesigner/landingpage/content/CustomCheckBox.ui.qml
blob: 8d91f695429e5da512f8d9698e64c189ab7a1a3e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
/****************************************************************************
**
** Copyright (C) 2022 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of Qt Creator.
**
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 as published by the Free Software
** Foundation with exceptions as appearing in the file LICENSE.GPL3-EXCEPT
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
****************************************************************************/

import QtQuick 2.15
import QtQuick.Templates 2.15
import LandingPage as Theme

CheckBox {
    id: control
    autoExclusive: false

    implicitWidth: Math.max(implicitBackgroundWidth + leftInset + rightInset,
                            implicitContentWidth + leftPadding + rightPadding)
    implicitHeight: Math.max(implicitBackgroundHeight + topInset + bottomInset,
                             implicitContentHeight + topPadding + bottomPadding,
                             implicitIndicatorHeight + topPadding + bottomPadding)

    spacing: Theme.Values.checkBoxSpacing
    hoverEnabled: true
    font.family: Theme.Values.baseFont

    indicator: Rectangle {
        id: checkBoxBackground
        implicitWidth: Theme.Values.checkBoxSize
        implicitHeight: Theme.Values.checkBoxSize
        x: 0
        y: parent.height / 2 - height / 2
        color: Theme.Colors.backgroundPrimary
        border.color: Theme.Colors.foregroundSecondary
        border.width: Theme.Values.border

        Rectangle {
            id: checkBoxIndicator
            width: Theme.Values.checkBoxIndicatorSize
            height: Theme.Values.checkBoxIndicatorSize
            x: (Theme.Values.checkBoxSize - Theme.Values.checkBoxIndicatorSize) * 0.5
            y: (Theme.Values.checkBoxSize - Theme.Values.checkBoxIndicatorSize) * 0.5
            color: Theme.Colors.accent
            visible: control.checked
        }
    }

    contentItem: Text {
        id: checkBoxLabel
        text: control.text
        font: control.font
        color: Theme.Colors.text
        verticalAlignment: Text.AlignVCenter
        leftPadding: control.indicator.width + control.spacing
    }

    states: [
        State {
            name: "default"
            when: control.enabled && !control.hovered && !control.pressed
            PropertyChanges {
                target: checkBoxBackground
                color: Theme.Colors.backgroundPrimary
                border.color: Theme.Colors.foregroundSecondary
            }
            PropertyChanges {
                target: checkBoxLabel
                color: Theme.Colors.text
            }
        },
        State {
            name: "hover"
            when: control.enabled && control.hovered && !control.pressed
            PropertyChanges {
                target: checkBoxBackground
                color: Theme.Colors.hover
                border.color: Theme.Colors.foregroundSecondary
            }
        },
        State {
            name: "press"
            when: control.hovered && control.pressed
            PropertyChanges {
                target: checkBoxBackground
                color: Theme.Colors.hover
                border.color: Theme.Colors.accent
            }
            PropertyChanges {
                target: checkBoxIndicator
                color: Theme.Colors.backgroundSecondary
            }
        },
        State {
            name: "disable"
            when: !control.enabled
            PropertyChanges {
                target: checkBoxBackground
                color: Theme.Colors.backgroundPrimary
                border.color: Theme.Colors.disabledLink
            }
            PropertyChanges {
                target: checkBoxIndicator
                color: Theme.Colors.disabledLink
            }
            PropertyChanges {
                target: checkBoxLabel
                color: Theme.Colors.disabledLink
            }
        }
    ]
}

/*##^##
Designer {
    D{i:0;height:40;width:142}
}
##^##*/