1 files changed, 80 insertions, 0 deletions
diff --git a/examples/quick3d/intro/main.qml b/examples/quick3d/intro/main.qml
new file mode 100644
index 000000000..648cfcf5c
--- /dev/null
+++ b/examples/quick3d/intro/main.qml
@@ -0,0 +1,80 @@
+// Copyright (C) 2021 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+//! [import]
+import QtQuick
+import QtQuick3D
+//! [import]
+
+Window {
+    id: window
+    width: 1280
+    height: 720
+    visible: true
+
+    View3D {
+        id: view
+        anchors.fill: parent
+
+        //! [environment]
+        environment: SceneEnvironment {
+            clearColor: "skyblue"
+            backgroundMode: SceneEnvironment.Color
+        }
+        //! [environment]
+
+        //! [camera]
+        PerspectiveCamera {
+            position: Qt.vector3d(0, 200, 300)
+            eulerRotation.x: -30
+        }
+        //! [camera]
+
+        //! [light]
+        DirectionalLight {
+            eulerRotation.x: -30
+            eulerRotation.y: -70
+        }
+        //! [light]
+
+        //! [objects]
+        Model {
+            position: Qt.vector3d(0, -200, 0)
+            source: "#Cylinder"
+            scale: Qt.vector3d(2, 0.2, 1)
+            materials: [ DefaultMaterial {
+                    diffuseColor: "red"
+                }
+            ]
+        }
+
+        Model {
+            position: Qt.vector3d(0, 150, 0)
+            source: "#Sphere"
+
+            materials: [ DefaultMaterial {
+                    diffuseColor: "blue"
+                }
+            ]
+
+            //! [animation]
+            SequentialAnimation on y {
+                loops: Animation.Infinite
+                NumberAnimation {
+                    duration: 3000
+                    to: -150
+                    from: 150
+                    easing.type:Easing.InQuad
+                }
+                NumberAnimation {
+                    duration: 3000
+                    to: 150
+                    from: -150
+                    easing.type:Easing.OutQuad
+                }
+            }
+            //! [animation]
+        }
+        //! [objects]
+    }
+}