blob: db6aa7145233950bad8b3111e1c6725ebaf9dff4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
// Copyright (C) 2022 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
import QtQuick
import QtQuick.Layouts
import HeartRateGame
Item {
id: app
required property ConnectionHandler connectionHandler
required property DeviceFinder deviceFinder
required property DeviceHandler deviceHandler
anchors.fill: parent
opacity: 0.0
Behavior on opacity {
NumberAnimation {
duration: 500
}
}
property int __currentIndex: 0
TitleBar {
id: titleBar
anchors.top: parent.top
anchors.left: parent.left
anchors.right: parent.right
currentIndex: app.__currentIndex
onTitleClicked: (index) => {
if (index < app.__currentIndex)
app.__currentIndex = index
}
}
StackLayout {
id: pageStack
anchors.left: parent.left
anchors.right: parent.right
anchors.top: titleBar.bottom
anchors.bottom: parent.bottom
currentIndex: app.__currentIndex
Connect {
connectionHandler: app.connectionHandler
deviceFinder: app.deviceFinder
deviceHandler: app.deviceHandler
onShowMeasurePage: app.__currentIndex = 1
}
Measure {
id: measurePage
deviceHandler: app.deviceHandler
onShowStatsPage: app.__currentIndex = 2
}
Stats {
deviceHandler: app.deviceHandler
}
onCurrentIndexChanged: {
if (currentIndex === 0)
measurePage.close()
}
}
BluetoothAlarmDialog {
id: btAlarmDialog
anchors.fill: parent
visible: !app.connectionHandler.alive || permissionError
permissionError: !app.connectionHandler.hasPermission
}
Keys.onReleased: (event) => {
switch (event.key) {
case Qt.Key_Escape:
case Qt.Key_Back:
{
if (app.__currentIndex > 0) {
app.__currentIndex = app.__currentIndex - 1
event.accepted = true
} else {
Qt.quit()
}
break
}
default:
break
}
}
Component.onCompleted: {
forceActiveFocus()
app.opacity = 1.0
}
}
|
