blob: 8213c57471f3ce563f0f5c37c7a41307488ffa04 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
|
// Copyright (C) 2023 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
import QtQuick
import QtQuick.Controls
import QtDataVisualization
Rectangle {
id: heightMapView
color: surfacePlot.theme.windowColor
required property bool portraitMode
property real buttonWidth: heightMapView.portraitMode ? (heightMapView.width - 35) / 2
: (heightMapView.width - 40) / 3
Item {
id: surfaceView
anchors.top: buttons.bottom
anchors.bottom: heightMapView.bottom
anchors.left: heightMapView.left
anchors.right: heightMapView.right
//! [1]
ColorGradient {
id: surfaceGradient
ColorGradientStop { position: 0.0; color: "darkgreen"}
ColorGradientStop { position: 0.15; color: "darkslategray" }
ColorGradientStop { position: 0.7; color: "peru" }
ColorGradientStop { position: 1.0; color: "white" }
}
//! [1]
Surface3D {
id: surfacePlot
width: surfaceView.width
height: surfaceView.height
aspectRatio: 3.0
//! [2]
theme: Theme3D {
type: Theme3D.ThemeStoneMoss
font.family: "STCaiyun"
font.pointSize: 35
colorStyle: Theme3D.ColorStyleRangeGradient
baseGradients: [surfaceGradient] // Use the custom gradient
}
//! [2]
shadowQuality: AbstractGraph3D.ShadowQualityMedium
selectionMode: AbstractGraph3D.SelectionSlice | AbstractGraph3D.SelectionItemAndRow
scene.activeCamera.cameraPreset: Camera3D.CameraPresetIsometricLeft
axisX.segmentCount: 3
axisX.subSegmentCount: 3
axisX.labelFormat: "%i"
axisZ.segmentCount: 3
axisZ.subSegmentCount: 3
axisZ.labelFormat: "%i"
axisY.segmentCount: 2
axisY.subSegmentCount: 2
axisY.labelFormat: "%i"
axisY.title: "Height (m)"
axisX.title: "Longitude 175.x\"E"
axisZ.title: "Latitude -39.x\"N"
axisY.titleVisible: true
axisX.titleVisible: true
axisZ.titleVisible: true
//! [0]
Surface3DSeries {
id: heightSeries
flatShadingEnabled: false
drawMode: Surface3DSeries.DrawSurface
HeightMapSurfaceDataProxy {
heightMapFile: ":/qml/qmlsurfacegallery/heightmap.png"
// We don't want the default data values set by heightmap proxy, but use
// actual coordinate and height values instead
autoScaleY: true
minYValue: 740
maxYValue: 2787
minZValue: -374 // ~ -39.374411"N
maxZValue: -116 // ~ -39.115971"N
minXValue: 472 // ~ 175.471767"E
maxXValue: 781 // ~ 175.780758"E
}
onDrawModeChanged: heightMapView.checkState()
}
//! [0]
}
}
Item {
id: buttons
anchors.top: parent.top
anchors.left: parent.left
anchors.right: parent.right
anchors.margins: 10
height: heightMapView.portraitMode ? surfaceGridToggle.implicitHeight * 3 + 20
: surfaceGridToggle.implicitHeight * 2 + 15
opacity: 0.5
Button {
id: surfaceGridToggle
anchors.margins: 5
anchors.left: parent.left
anchors.top: parent.top
width: heightMapView.buttonWidth // Calculated elsewhere based on screen orientation
text: "Show Surface\nGrid"
//! [3]
onClicked: {
if (heightSeries.drawMode & Surface3DSeries.DrawWireframe)
heightSeries.drawMode &= ~Surface3DSeries.DrawWireframe;
else
heightSeries.drawMode |= Surface3DSeries.DrawWireframe;
}
//! [3]
}
Button {
id: surfaceGridColor
anchors.margins: 5
anchors.left: surfaceGridToggle.right
anchors.top: parent.top
width: heightMapView.buttonWidth
text: "Red surface\ngrid color"
//! [4]
onClicked: {
if (Qt.colorEqual(heightSeries.wireframeColor, "#000000")) {
heightSeries.wireframeColor = "red";
text = "Black surface\ngrid color";
} else {
heightSeries.wireframeColor = "black";
text = "Red surface\ngrid color";
}
}
//! [4]
}
Button {
id: surfaceToggle
anchors.margins: 5
anchors.left: heightMapView.portraitMode ? parent.left : surfaceGridColor.right
anchors.top: heightMapView.portraitMode ? surfaceGridColor.bottom : parent.top
width: heightMapView.buttonWidth
text: "Hide\nSurface"
//! [5]
onClicked: {
if (heightSeries.drawMode & Surface3DSeries.DrawSurface)
heightSeries.drawMode &= ~Surface3DSeries.DrawSurface;
else
heightSeries.drawMode |= Surface3DSeries.DrawSurface;
}
//! [5]
}
Button {
id: flatShadingToggle
anchors.margins: 5
anchors.left: heightMapView.portraitMode ? surfaceToggle.right : parent.left
anchors.top: heightMapView.portraitMode ? surfaceGridColor.bottom : surfaceToggle.bottom
width: heightMapView.buttonWidth
text: heightSeries.flatShadingSupported ? "Show\nFlat" : "Flat not\nsupported"
enabled: heightSeries.flatShadingSupported
//! [6]
onClicked: {
if (heightSeries.flatShadingEnabled) {
heightSeries.flatShadingEnabled = false;
text = "Show\nFlat"
} else {
heightSeries.flatShadingEnabled = true;
text = "Show\nSmooth"
}
}
//! [6]
}
Button {
id: backgroundToggle
anchors.margins: 5
anchors.left: heightMapView.portraitMode ? parent.left : flatShadingToggle.right
anchors.top: heightMapView.portraitMode ? flatShadingToggle.bottom
: surfaceToggle.bottom
width: heightMapView.buttonWidth
text: "Hide\nBackground"
onClicked: {
if (surfacePlot.theme.backgroundEnabled) {
surfacePlot.theme.backgroundEnabled = false;
text = "Show\nBackground";
} else {
surfacePlot.theme.backgroundEnabled = true;
text = "Hide\nBackground";
}
}
}
Button {
id: gridToggle
anchors.margins: 5
anchors.left: backgroundToggle.right
anchors.top: heightMapView.portraitMode ? flatShadingToggle.bottom
: surfaceToggle.bottom
width: heightMapView.buttonWidth
text: "Hide\nGrid"
onClicked: {
if (surfacePlot.theme.gridEnabled) {
surfacePlot.theme.gridEnabled = false;
text = "Show\nGrid";
} else {
surfacePlot.theme.gridEnabled = true;
text = "Hide\nGrid";
}
}
}
}
function checkState() {
if (heightSeries.drawMode & Surface3DSeries.DrawSurface)
surfaceToggle.text = "Hide\nSurface";
else
surfaceToggle.text = "Show\nSurface";
if (heightSeries.drawMode & Surface3DSeries.DrawWireframe)
surfaceGridToggle.text = "Hide Surface\nGrid";
else
surfaceGridToggle.text = "Show Surface\nGrid";
}
}
|