Extract generation of extra files into own .pro filesv4.0.3v4.0.24.0

There was still some kind of dependency resolution problem. Now the
dependencies are specified one level higher, in the libcpu.pro file,
which should be more robust than the inline specification in i386.pro,
x86_64.pro, and i386_gendis.pro.

Change-Id: I21c5d27a6be9e7b08f3d55a16fe78a66585932a7
Reviewed-by: Christian Kandeler <christian.kandeler@theqtcompany.com>
Reviewed-by: Eike Ziller <eike.ziller@qt.io>

9 files changed, 66 insertions, 55 deletions

diff --git a/3rdparty/elfutils/libcpu/extras.mk b/3rdparty/elfutils/libcpu/extras.mk
index e71bb6e..2f83719 100644
--- a/3rdparty/elfutils/libcpu/extras.mk
+++ b/3rdparty/elfutils/libcpu/extras.mk
@@ -7,7 +7,7 @@
 	sed '1,/^%%/d;/^#/d;/^[[:space:]]*$$/d;s/[^:]*:\([^[:space:]]*\).*/MNE(\1)/;s/{[^}]*}//g;/INVALID/d' \
 	  $< | sort -u > $@
 
-%_dis.h: $(gendis)/%_defs $(gendis)/i386_gendis
+%_dis.h: $(mnemonics)/%_defs $(gendis)/i386_gendis
 	$(gendis)/i386_gendis $< > $@T
 	mv -f $@T $@
 
diff --git a/3rdparty/elfutils/libcpu/i386/i386.pro b/3rdparty/elfutils/libcpu/i386/i386.pro
index ec1090b..d9945eb 100644
--- a/3rdparty/elfutils/libcpu/i386/i386.pro
+++ b/3rdparty/elfutils/libcpu/i386/i386.pro
@@ -6,27 +6,13 @@ include(../../libasm/asmheaders.pri)
 include(../../libebl/eblheaders.pri)
 include(../cpuheaders.pri)
 
-gendis.target = i386_dis.h
-gendis.commands = make -f $$PWD/../extras.mk gendis=$$OUT_PWD/../i386_gendis/ srcdir=$$PWD/../ \
-    i386_dis.h
-i386.depends = i386_dis.h
-
-OTHER_FILES += \
-    $$PWD/../extras.mk
-
 SOURCES += \
     $$PWD/../i386_disasm.c
 
 INCLUDEPATH += \
-    $$OUT_PWD/../i386_gendis \
-    $$OUT_PWD
+    $$OUT_PWD/../i386_mnemonics \
+    $$OUT_PWD/../i386_dis
 
 GENERATED_HEADERS += \
-    $$OUT_PWD/i386_dis.h \
-    $$OUT_PWD/../i386_gendis/i386.mnemonics
-
-QMAKE_EXTRA_TARGETS += \
-    gendis
-
-PRE_TARGETDEPS += \
-    i386_dis.h
+    $$OUT_PWD/../i386_dis/i386_dis.h \
+    $$OUT_PWD/../i386_mnemonics/i386.mnemonics
diff --git a/3rdparty/elfutils/libcpu/i386_dis/i386_dis.pro b/3rdparty/elfutils/libcpu/i386_dis/i386_dis.pro
new file mode 100644
index 0000000..be81102
--- /dev/null
+++ b/3rdparty/elfutils/libcpu/i386_dis/i386_dis.pro
@@ -0,0 +1,11 @@
+TEMPLATE = aux
+DESTDIR = $$OUT_PWD/..
+
+gendis.target = i386_dis.h
+gendis.commands = make -f $$PWD/../extras.mk mnemonics=$$OUT_PWD/../i386_mnemonics/ \
+    gendis=$$OUT_PWD/../i386_gendis/ srcdir=$$PWD/../ i386_dis.h
+
+QMAKE_EXTRA_TARGETS += gendis
+PRE_TARGETDEPS += i386_dis.h
+
+OTHER_FILES += $$PWD/../extras.mk
diff --git a/3rdparty/elfutils/libcpu/i386_gendis/i386_gendis.pro b/3rdparty/elfutils/libcpu/i386_gendis/i386_gendis.pro
index 180afc4..667760e 100644
--- a/3rdparty/elfutils/libcpu/i386_gendis/i386_gendis.pro
+++ b/3rdparty/elfutils/libcpu/i386_gendis/i386_gendis.pro
@@ -6,12 +6,6 @@ QMAKE_CFLAGS += -Wno-unused-function
 include(../../elfutils.pri)
 include(../../lib/libheaders.pri)
 
-mnemonics32.target = i386.mnemonics
-mnemonics32.commands = make -f $$PWD/../extras.mk srcdir=$$PWD/../ i386.mnemonics
-
-mnemonics64.target = x86_64.mnemonics
-mnemonics64.commands = make -f $$PWD/../extras.mk srcdir=$$PWD/../ x86_64.mnemonics
-
 mylex.target = i386_lex.c
 mylex.depends = i386_parse.c
 mylex.commands = flex -Pi386_ -o i386_lex.c $$PWD/../i386_lex.l
@@ -20,8 +14,6 @@ myyacc.target = i386_parse.c
 myyacc.commands = bison -pi386_ -d -o i386_parse.c $$PWD/../i386_parse.y
 
 OTHER_FILES += \
-    $$PWD/../extras.mk \
-    $$PWD/../defs/i386 \
     $$PWD/../i386_lex.l \
     $$PWD/../i386_parse.y
 
@@ -35,14 +27,8 @@ GENERATED_SOURCES += \
 GENERATED_HEADERS += \
     i386_parse.h
 
-PRE_TARGETDEPS += \
-    i386.mnemonics \
-    x86_64.mnemonics
-
 QMAKE_EXTRA_TARGETS += \
     mylex \
-    myyacc \
-    mnemonics32 \
-    mnemonics64
+    myyacc
 
-DEFINES += NMNES='$(shell wc -l < i386.mnemonics)'
+DEFINES += NMNES='$(shell wc -l < ../i386_mnemonics/i386.mnemonics)'
diff --git a/3rdparty/elfutils/libcpu/i386_mnemonics/i386_mnemonics.pro b/3rdparty/elfutils/libcpu/i386_mnemonics/i386_mnemonics.pro
new file mode 100644
index 0000000..20304c1
--- /dev/null
+++ b/3rdparty/elfutils/libcpu/i386_mnemonics/i386_mnemonics.pro
@@ -0,0 +1,12 @@
+TEMPLATE = aux
+DESTDIR = $$OUT_PWD/..
+
+mnemonics.target = i386.mnemonics
+mnemonics.commands = make -f $$PWD/../extras.mk srcdir=$$PWD/../ i386.mnemonics
+
+OTHER_FILES = \
+    $$PWD/../extras.mk \
+    $$PWD/../defs/i386 \
+
+QMAKE_EXTRA_TARGETS += mnemonics
+PRE_TARGETDEPS += i386.mnemonics
diff --git a/3rdparty/elfutils/libcpu/libcpu.pro b/3rdparty/elfutils/libcpu/libcpu.pro
index 1a4fac7..05bd6ab 100644
--- a/3rdparty/elfutils/libcpu/libcpu.pro
+++ b/3rdparty/elfutils/libcpu/libcpu.pro
@@ -1,9 +1,16 @@
 TEMPLATE = subdirs
 
 SUBDIRS = \
+    i386_dis \
     i386_gendis \
+    i386_mnemonics \
     i386 \
+    x86_64_dis \
+    x86_64_mnemonics \
     x86_64
 
-i386.depends = i386_gendis
-x86_64.depends = i386_gendis
+i386_gendis.depends = i386_mnemonics
+i386_dis.depends = i386_gendis i386_mnemonics
+x86_64_dis.depends = i386_gendis x86_64_mnemonics
+i386.depends = i386_dis
+x86_64.depends = x86_64_dis
diff --git a/3rdparty/elfutils/libcpu/x86_64/x86_64.pro b/3rdparty/elfutils/libcpu/x86_64/x86_64.pro
index 7672cc2..45cfc30 100644
--- a/3rdparty/elfutils/libcpu/x86_64/x86_64.pro
+++ b/3rdparty/elfutils/libcpu/x86_64/x86_64.pro
@@ -6,27 +6,13 @@ include(../../libasm/asmheaders.pri)
 include(../../libebl/eblheaders.pri)
 include(../cpuheaders.pri)
 
-gendis.target = x86_64_dis.h
-gendis.commands = make -f $$PWD/../extras.mk gendis=$$OUT_PWD/../i386_gendis/ srcdir=$$PWD/../ \
-    x86_64_dis.h
-x86_64.depends = x86_64_dis.h
-
-OTHER_FILES += \
-    $$PWD/../extras.mk
-
 SOURCES += \
     $$PWD/../x86_64_disasm.c
 
 INCLUDEPATH += \
-    $$OUT_PWD/../i386_gendis \
-    $$OUT_PWD
+    $$OUT_PWD/../x86_64_mnemonics \
+    $$OUT_PWD/../x86_64_dis
 
 GENERATED_HEADERS += \
-    $$OUT_PWD/x86_64_dis.h \
-    $$OUT_PWD/../i386_gendis/x86_64.mnemonics
-
-QMAKE_EXTRA_TARGETS += \
-    gendis
-
-PRE_TARGETDEPS += \
-    x86_64_dis.h
+    $$OUT_PWD/../x86_64_dis/x86_64_dis.h \
+    $$OUT_PWD/../x86_64_mnemonics/x86_64.mnemonics
diff --git a/3rdparty/elfutils/libcpu/x86_64_dis/x86_64_dis.pro b/3rdparty/elfutils/libcpu/x86_64_dis/x86_64_dis.pro
new file mode 100644
index 0000000..59cd516
--- /dev/null
+++ b/3rdparty/elfutils/libcpu/x86_64_dis/x86_64_dis.pro
@@ -0,0 +1,11 @@
+TEMPLATE = aux
+DESTDIR = $$OUT_PWD/..
+
+gendis.target = x86_64_dis.h
+gendis.commands = make -f $$PWD/../extras.mk mnemonics=$$OUT_PWD/../x86_64_mnemonics/ \
+    gendis=$$OUT_PWD/../i386_gendis/ srcdir=$$PWD/../ x86_64_dis.h
+
+QMAKE_EXTRA_TARGETS += gendis
+PRE_TARGETDEPS += x86_64_dis.h
+
+OTHER_FILES += $$PWD/../extras.mk
diff --git a/3rdparty/elfutils/libcpu/x86_64_mnemonics/x86_64_mnemonics.pro b/3rdparty/elfutils/libcpu/x86_64_mnemonics/x86_64_mnemonics.pro
new file mode 100644
index 0000000..fb1a1b2
--- /dev/null
+++ b/3rdparty/elfutils/libcpu/x86_64_mnemonics/x86_64_mnemonics.pro
@@ -0,0 +1,12 @@
+TEMPLATE = aux
+DESTDIR = $$OUT_PWD/..
+
+mnemonics.target = x86_64.mnemonics
+mnemonics.commands = make -f $$PWD/../extras.mk srcdir=$$PWD/../ x86_64.mnemonics
+
+OTHER_FILES = \
+    $$PWD/../extras.mk \
+    $$PWD/../defs/i386 \
+
+QMAKE_EXTRA_TARGETS += mnemonics
+PRE_TARGETDEPS += x86_64.mnemonics