blob: 496d2ebe35c9ce27c996a15090b3f60744259ccd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
include(../../qtcreator.pri)
include(../shared/qtsingleapplication/qtsingleapplication.pri)
TEMPLATE = app
CONFIG += qtc_runnable
TARGET = $$IDE_APP_TARGET
DESTDIR = $$IDE_APP_PATH
QT -= testlib
HEADERS += ../tools/qtcreatorcrashhandler/crashhandlersetup.h
SOURCES += main.cpp ../tools/qtcreatorcrashhandler/crashhandlersetup.cpp
include(../rpath.pri)
LIBS *= -l$$qtLibraryName(ExtensionSystem) -l$$qtLibraryName(Aggregation) -l$$qtLibraryName(Utils)
QT_BREAKPAD_ROOT_PATH = $$(QT_BREAKPAD_ROOT_PATH)
!isEmpty(QT_BREAKPAD_ROOT_PATH) {
include($$QT_BREAKPAD_ROOT_PATH/qtbreakpad.pri)
}
win32 {
RC_FILE = qtcreator.rc
target.path = $$INSTALL_BIN_PATH
INSTALLS += target
} else:macx {
LIBS += -framework CoreFoundation
ICON = qtcreator.icns
FILETYPES.files = profile.icns prifile.icns
FILETYPES.path = Contents/Resources
QMAKE_BUNDLE_DATA += FILETYPES
info.input = Info.plist.in
info.output = $$IDE_BIN_PATH/../Info.plist
QMAKE_SUBSTITUTES = info
} else {
target.path = $$INSTALL_BIN_PATH
INSTALLS += target
}
DISTFILES += qtcreator.rc \
Info.plist.in \
$$PWD/app_version.h.in
QMAKE_SUBSTITUTES += $$PWD/app_version.h.in
CONFIG += no_batch
|