fix rcc & uic .depend_commands

unlike the .command, the .depend_command is not executed by make via its
chosen shell, but qmake itself via the system's native shell.
consequently, it needs different path separators and no make-escaping.

Task-number: QTBUG-31289
Change-Id: I480f815753632db6e8d4725f463f8a1fc59680a6
Reviewed-by: Joerg Bornemann <joerg.bornemann@digia.com>

3 files changed, 30 insertions, 11 deletions

diff --git a/mkspecs/features/qt_functions.prf b/mkspecs/features/qt_functions.prf
index ca8391b65a..63ae62c42e 100644
--- a/mkspecs/features/qt_functions.prf
+++ b/mkspecs/features/qt_functions.prf
@@ -189,7 +189,7 @@ defineTest(qtAddRpathLink) {
     export(QMAKE_RPATHLINKDIR)
 }
 
-# variable, default
+# variable, default, [suffix for variable for system() use]
 defineTest(qtPrepareTool) {
     $$1 = $$eval(QT_TOOL.$${2}.binary)
     isEmpty($$1) {
@@ -205,16 +205,25 @@ defineTest(qtPrepareTool) {
             }
         }
     }
+    !isEmpty(3) {
+        $$1$$3 = $$system_path($$eval($$1))
+        qtAddTargetEnv($$1$$3, QT_TOOL.$${2}.depends, system)
+    }
     $$1 = $$shell_path($$eval($$1))
     qtAddTargetEnv($$1, QT_TOOL.$${2}.depends)
 }
 
+# target variable, list of env var names, [non-empty: prepare for system(), not make]
 defineTest(qtAddToolEnv) {
+    isEmpty(3): \
+        ds = $$QMAKE_DIR_SEP
+    else: \
+        ds = $$DIR_SEPARATOR
     for(env, 2) {
         value = $$eval($${env}.value)
         !isEmpty(value) {
             name = $$eval($${env}.name)
-            equals(QMAKE_DIR_SEP, /) {
+            equals(ds, /) {
                 contains($${env}.CONFIG, prepend): infix = \${$$name:+:\$$$name}
                 else: infix =
                 val = "$$name=$$join(value, :)$$infix"
@@ -224,7 +233,7 @@ defineTest(qtAddToolEnv) {
                 else: infix =
                 val = "(set $$name=$$join(value, ;)$$infix) &"
             }
-            !contains(TEMPLATE, vc.*) {
+            isEmpty(3): !contains(TEMPLATE, vc.*) {
                 contains(MAKEFILE_GENERATOR, MS.*): val ~= s,%,%%,g
                 val ~= s,\\\$,\$\$,g
             }
@@ -234,12 +243,17 @@ defineTest(qtAddToolEnv) {
     export($$1)
 }
 
+# target variable, dependency var name, [non-empty: prepare for system(), not make]
 defineTest(qtAddTargetEnv) {
     deps = $$replace($$2, -private$, )
     deps = $$resolve_depends(deps, "QT.", ".depends" ".private_depends" ".run_depends")
     !isEmpty(deps) {
-        for(dep, deps): \
-            deppath += $$shell_path($$eval(QT.$${dep}.libs))
+        for(dep, deps) {
+            isEmpty(3): \
+                deppath += $$shell_path($$eval(QT.$${dep}.libs))
+            else: \
+                deppath += $$system_path($$eval(QT.$${dep}.libs))
+        }
         equals(QMAKE_HOST.os, Windows) {
             deppath.name = PATH
         } else:contains(QMAKE_HOST.os, Linux|FreeBSD) {
@@ -258,13 +272,18 @@ defineTest(qtAddTargetEnv) {
         pluginpath.value =
         for(qmod, QMAKEMODULES) {
             qmod = $$section(qmod, /, 0, -3)/plugins
-            exists($$qmod): pluginpath.value += $$shell_path($$qmod)
+            exists($$qmod) {
+                isEmpty(3): \
+                    pluginpath.value += $$shell_path($$qmod)
+                else: \
+                    pluginpath.value += $$system_path($$qmod)
+            }
         }
         pluginpath.name = QT_PLUGIN_PATH
 
         QT_TOOL_ENV += deppath pluginpath
     }
-    qtAddToolEnv($$1, $$QT_TOOL_ENV)
+    qtAddToolEnv($$1, $$QT_TOOL_ENV, $$3)
 }
 
 defineReplace(pkgConfigExecutable) {
diff --git a/mkspecs/features/resources.prf b/mkspecs/features/resources.prf
index 34a04b4ee2..68ca4d1442 100644
--- a/mkspecs/features/resources.prf
+++ b/mkspecs/features/resources.prf
@@ -1,4 +1,4 @@
-qtPrepareTool(QMAKE_RCC, rcc)
+qtPrepareTool(QMAKE_RCC, rcc, _DEP)
 
 isEmpty(RCC_DIR):RCC_DIR = .
 isEmpty(QMAKE_MOD_RCC):QMAKE_MOD_RCC = qrc
@@ -19,7 +19,7 @@ resource_combine {
     }
 }
 rcc.commands = $$QMAKE_RCC $$QMAKE_RESOURCE_FLAGS ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
-rcc.depend_command = $$QMAKE_RCC -list $$QMAKE_RESOURCE_FLAGS ${QMAKE_FILE_IN}
+rcc.depend_command = $$QMAKE_RCC_DEP -list $$QMAKE_RESOURCE_FLAGS ${QMAKE_FILE_IN}
 rcc.CONFIG += add_inputs_as_makefile_deps
 rcc.input = RESOURCES
 rcc.variable_out = SOURCES
diff --git a/mkspecs/features/uic.prf b/mkspecs/features/uic.prf
index 83e579cb3a..c6a64050e0 100644
--- a/mkspecs/features/uic.prf
+++ b/mkspecs/features/uic.prf
@@ -1,10 +1,10 @@
-qtPrepareTool(QMAKE_UIC, uic)
+qtPrepareTool(QMAKE_UIC, uic, _DEP)
 
 isEmpty(UI_DIR):UI_DIR = .
 isEmpty(QMAKE_MOD_UIC):QMAKE_MOD_UIC = ui_
 
 uic.commands = $$QMAKE_UIC ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
-uic.depend_command = $$QMAKE_UIC -d ${QMAKE_FILE_IN}
+uic.depend_command = $$QMAKE_UIC_DEP -d ${QMAKE_FILE_IN}
 uic.output = $$UI_DIR/$${QMAKE_MOD_UIC}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_H)}
 uic.input = FORMS
 uic.variable_out = GENERATED_FILES