winrt: Add capabilities as specified by modules

So far no capabilities (but internetClient for Windows 10) were added by
default, which forced developers to always manually edit the
WINRT_MANIFEST.capabilities(_device) property.

This allowed to leave out non-required capabilities and keep the created
manifest clean, examples being microphone for multimedia.

However, this also breaks first user experience as deeper knowledge
about this topic is required. Furthermore this is inconsistent with
other platforms like Android, where all capabilities are set by default
and developers need to edit the manifest manually in any case.
With this change, modules can define the capability set to enable all
features in the module. If developers want to disable some again, they
need to adapt the generated manifest. From our experience this needs to
be done in any case, latest at publishing stage when the store
manipulates the manifest.

Task-number: QTBUG-38802
Change-Id: I6d522268ee0afbfa00a30dbdd5e6ec9f415bebf3
Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@theqtcompany.com>

5 files changed, 31 insertions, 2 deletions

diff --git a/mkspecs/common/winrt_winphone/qmake.conf b/mkspecs/common/winrt_winphone/qmake.conf
index a9450b0c32..b5e0c7cc71 100644
--- a/mkspecs/common/winrt_winphone/qmake.conf
+++ b/mkspecs/common/winrt_winphone/qmake.conf
@@ -9,7 +9,7 @@ include(../angle.conf)
 MAKEFILE_GENERATOR      = MSBUILD
 QMAKE_COMPILER          = msvc
 QMAKE_PLATFORM          = winrt win32
-CONFIG                 += incremental flat precompile_header autogen_precompile_source debug_and_release debug_and_release_target package_manifest rtti
+CONFIG                  = package_manifest $$CONFIG incremental flat precompile_header autogen_precompile_source debug_and_release debug_and_release_target rtti
 DEFINES                += UNICODE WIN32 QT_LARGEFILE_SUPPORT Q_BYTE_ORDER=Q_LITTLE_ENDIAN \
                           QT_NO_PRINTER QT_NO_PRINTDIALOG # TODO: Remove when printing is re-enabled
 
@@ -95,6 +95,9 @@ VCSOLUTION_EXTENSION    = .sln
 VCPROJ_KEYWORD          = Qt4VSv1.0
 WINRT_ASSETS_PATH       = $$PWD/assets
 
+WINRT_MANIFEST.capabilities = defaults
+WINRT_MANIFEST.capabilities_device = defaults
+
 include(../msvc-base.conf)
 
 unset(MSC_VER)
diff --git a/mkspecs/features/qt.prf b/mkspecs/features/qt.prf
index 5cc176c2ae..75b84ff6aa 100644
--- a/mkspecs/features/qt.prf
+++ b/mkspecs/features/qt.prf
@@ -141,6 +141,15 @@ for(ever) {
                 }
             }
         }
+        # Add capabilities as defined by modules used in the project
+        winrt {
+            MODULE_WINRT_CAPABILITIES = $$eval(QT.$${QTLIB}.winrt_capabilities)
+            !isEmpty(MODULE_WINRT_CAPABILITIES): \
+                WINRT_MANIFEST.capabilities_default += $$MODULE_WINRT_CAPABILITIES
+            MODULE_WINRT_CAPABILITIES_DEVICE = $$eval(QT.$${QTLIB}.winrt_capabilities_device)
+            !isEmpty(MODULE_WINRT_CAPABILITIES_DEVICE): \
+                WINRT_MANIFEST.capabilities_device_default += $$MODULE_WINRT_CAPABILITIES_DEVICE
+        }
     }
     !isEmpty(BAD_QT):error("Unknown module(s) in QT$$var_sfx: $$replace(BAD_QT, _private$, -private)")
 
diff --git a/mkspecs/features/qt_module_pris.prf b/mkspecs/features/qt_module_pris.prf
index 9c45350543..4dd9e25f9f 100644
--- a/mkspecs/features/qt_module_pris.prf
+++ b/mkspecs/features/qt_module_pris.prf
@@ -104,6 +104,9 @@ MODULE_FWD_PRI = $$mod_work_pfx/qt_lib_$${MODULE_ID}.pri
         "QT.$${MODULE_ID}.DEFINES = $$val_escape(MODULE_DEFINES)" \
         "" \
         "QT_MODULES += $$MODULE"
+    winrt: MODULE_PRI_CONT += \
+        "QT.$${MODULE_ID}.winrt_capabilities =$$join(MODULE_WINRT_CAPABILITIES, " ", " ")" \
+        "QT.$${MODULE_ID}.winrt_capabilities_device =$$join(MODULE_WINRT_CAPABILITIES_DEVICE, " ", " ")"
     write_file($$MODULE_PRI, MODULE_PRI_CONT)|error("Aborting.")
     !internal_module:!no_private_module {
         module_build_type += internal_module
@@ -186,6 +189,7 @@ MODULE_FWD_PRI = $$mod_work_pfx/qt_lib_$${MODULE_ID}.pri
         for(var, $$list(VERSION MAJOR_VERSION MINOR_VERSION PATCH_VERSION \
                         name module depends run_depends plugin_types module_config CONFIG DEFINES \
                         priority includes bins libs frameworks libexecs plugins imports qml \
+                        winrt_capabilities winrt_capabilities_device \
                 )):defined(QT.$${mod}.$$var, var):cache(QT.$${mod}.$$var, transient)
     }
     cache(QT_MODULES, transient)
diff --git a/mkspecs/features/winrt/package_manifest.prf b/mkspecs/features/winrt/package_manifest.prf
index 3520fcdf93..291ebec6e9 100644
--- a/mkspecs/features/winrt/package_manifest.prf
+++ b/mkspecs/features/winrt/package_manifest.prf
@@ -112,10 +112,19 @@
     # capability anymore and is assumed to be standard.
     *-msvc2015: WINRT_MANIFEST.capabilities += internetClient
 
+    contains(WINRT_MANIFEST.capabilities, defaults) {
+        WINRT_MANIFEST.capabilities -= defaults
+        WINRT_MANIFEST.capabilities += $$WINRT_MANIFEST.capabilities_default
+    }
+
+    contains(WINRT_MANIFEST.capabilities_device, defaults) {
+        WINRT_MANIFEST.capabilities_device -= defaults
+        WINRT_MANIFEST.capabilities_device += $$WINRT_MANIFEST.capabilities_device_default
+    }
+
     # Capabilities are given as a string list and may change with the configuration (network, sensors, etc.)
     WINRT_MANIFEST.capabilities = $$unique(WINRT_MANIFEST.capabilities)
     WINRT_MANIFEST.capabilities_device = $$unique(WINRT_MANIFEST.capabilities_device)
-
     !isEmpty(WINRT_MANIFEST.capabilities)|!isEmpty(WINRT_MANIFEST.capabilities_device) {
         MANIFEST_CAPABILITIES += "<Capabilities>"
         for(CAPABILITY, WINRT_MANIFEST.capabilities): \
diff --git a/src/network/network.pro b/src/network/network.pro
index cdea190222..fed14616af 100644
--- a/src/network/network.pro
+++ b/src/network/network.pro
@@ -32,6 +32,10 @@ MODULE_PLUGIN_TYPES = \
 ANDROID_PERMISSIONS += \
     android.permission.ACCESS_NETWORK_STATE
 
+MODULE_WINRT_CAPABILITIES = \
+    internetClient \
+    internetClientServer
+
 MODULE_PLUGIN_TYPES = \
     bearer
 load(qt_module)