Move webengine sanitizer option to new configure system

Use new configure system to enable sanitizer.

Change-Id: I633bc96973b9b9bcd56c4ef03a589e147215dc86
Reviewed-by: Allan Sandfeld Jensen <allan.jensen@qt.io>

1 files changed, 89 insertions, 0 deletions

diff --git a/configure.pri b/configure.pri
index 549b1efd0..c88d4964b 100644
--- a/configure.pri
+++ b/configure.pri
@@ -156,3 +156,92 @@ defineTest(qtConfTest_detectIcuuc) {
    }
    return(false)
 }
+
+defineTest(qtConfTest_isSanitizerSupported) {
+  sanitizer_combo_supported = true
+  sanitize_address {
+    asan_supported = false
+    linux-clang-libc++:isSanitizerSupportedOnLinux() {
+      asan_supported = true
+    } else:macos:isSanitizerSupportedOnMacOS() {
+      asan_supported = true
+    }
+    !$$asan_supported {
+      sanitizer_combo_supported = false
+       qtLog("An address sanitizer-enabled Qt WebEngine build can only be built on Linux or macOS using Clang and libc++.")
+    }
+  }
+
+  sanitize_memory {
+    sanitizer_combo_supported = false
+    qtLog("A memory sanitizer-enabled Qt WebEngine build is not supported.")
+  }
+
+  sanitize_undefined {
+    ubsan_supported = false
+    linux-clang-libc++:isSanitizerSupportedOnLinux():CONFIG(release, debug|release):!debug_and_release {
+      ubsan_supported = true
+    }
+    !$$ubsan_supported {
+      sanitizer_combo_supported = false
+      qtLog("An undefined behavior sanitizer-enabled Qt WebEngine build can only be built on Linux using Clang and libc++ in release mode.")
+    }
+  }
+
+  sanitize_thread {
+    tsan_supported = false
+    linux-clang-libc++:isSanitizerSupportedOnLinux() {
+      tsan_supported = true
+    }
+    !$$tsan_supported {
+      sanitizer_combo_supported = false
+      qtLog("A thread sanitizer-enabled Qt WebEngine build can only be built on Linux using Clang and libc++.")
+    }
+  }
+
+  $$sanitizer_combo_supported: return(true)
+  return(false)
+}
+
+defineTest(isSanitizerSupportedOnLinux) {
+  isSanitizerLinuxClangVersionSupported(): return(true)
+  return(false)
+}
+
+defineTest(isSanitizerSupportedOnMacOS) {
+  isEmpty(QT_APPLE_CLANG_MAJOR_VERSION) {
+    QTWEBENGINE_CLANG_IS_APPLE = false
+  } else {
+    QTWEBENGINE_CLANG_IS_APPLE = true
+  }
+  $$QTWEBENGINE_CLANG_IS_APPLE:isSanitizerMacOSAppleClangVersionSupported(): return(true)
+  else:isSanitizerMacOSClangVersionSupported(): return(true)
+  return(false)
+}
+
+defineTest(isSanitizerMacOSAppleClangVersionSupported) {
+  # Clang sanitizer suppression attributes work from Apple Clang version 7.3.0+.
+  greaterThan(QT_APPLE_CLANG_MAJOR_VERSION, 7): return(true)
+  greaterThan(QT_APPLE_CLANG_MINOR_VERSION, 2): return(true)
+
+  qtLog("Using Apple Clang version $${QT_APPLE_CLANG_MAJOR_VERSION}.$${QT_APPLE_CLANG_MINOR_VERSION}.$${QT_APPLE_CLANG_PATCH_VERSION}, but at least Apple Clang version 7.3.0 is required to build a sanitizer-enabled Qt WebEngine.")
+  return(false)
+}
+
+defineTest(isSanitizerMacOSClangVersionSupported) {
+  # Clang sanitizer suppression attributes work from non-apple Clang version 3.7+.
+  greaterThan(QT_CLANG_MAJOR_VERSION, 3): return(true)
+  greaterThan(QT_CLANG_MINOR_VERSION, 6): return(true)
+
+  qtLog("Using Clang version $${QT_CLANG_MAJOR_VERSION}.$${QT_CLANG_MINOR_VERSION}, but at least Clang version 3.7 is required to build a sanitizer-enabled Qt WebEngine.")
+  return(false)
+}
+
+defineTest(isSanitizerLinuxClangVersionSupported) {
+  # Clang sanitizer suppression attributes work from Clang version 3.7+.
+  greaterThan(QT_CLANG_MAJOR_VERSION, 3): return(true)
+  greaterThan(QT_CLANG_MINOR_VERSION, 6): return(true)
+
+  qtLog("Using Clang version $${QT_CLANG_MAJOR_VERSION}.$${QT_CLANG_MINOR_VERSION}, but at least Clang version 3.7 is required to build a sanitizer-enabled Qt WebEngine.")
+  return(false)
+}