Print macOS toolchain info when configuring WebEngine

It's not always easy to determine what Xcode / clang version is used
when building WebEngine in the CI. Same for the OS version and other
toolchain details.

Print out the values at QtWebEngine configure time.
This will also help us when users provide build logs.

Change-Id: I413a6c5b6efb42c4411268ca46d07c2fb9b85cc3
Reviewed-by: Allan Sandfeld Jensen <allan.jensen@qt.io>
Reviewed-by: Kai Koehne <kai.koehne@qt.io>

1 files changed, 26 insertions, 0 deletions

diff --git a/configure.pri b/configure.pri
index 82a7de227..4ce40351a 100644
--- a/configure.pri
+++ b/configure.pri
@@ -260,3 +260,29 @@ defineReplace(qtConfFunc_isTestsInBuildParts) {
     contains(QT_BUILD_PARTS, tests): return(true)
     return(false)
 }
+
+defineReplace(webEngineGetMacOSVersion) {
+    value = $$system("sw_vers -productVersion 2>/dev/null")
+    return($$value)
+}
+
+defineReplace(webEngineGetMacOSSDKVersion) {
+    value = $$system("/usr/bin/xcodebuild -sdk $$QMAKE_MAC_SDK -version ProductVersion 2>/dev/null")
+    return($$value)
+}
+
+defineReplace(webEngineGetMacOSClangVerboseVersion) {
+    output = $$system("$$QMAKE_CXX --version 2>/dev/null", lines)
+    value = $$first(output)
+    return($$value)
+}
+
+defineTest(qtConfReport_macosToolchainVersion) {
+    arg = $$2
+    contains(arg, "macosVersion"): report_message = $$webEngineGetMacOSVersion()
+    contains(arg, "xcodeVersion"): report_message = "$$QMAKE_XCODE_VERSION"
+    contains(arg, "clangVersion"): report_message = $$webEngineGetMacOSClangVerboseVersion()
+    contains(arg, "sdkVersion"): report_message = $$webEngineGetMacOSSDKVersion()
+    contains(arg, "deploymentTarget"): report_message = "$$QMAKE_MACOSX_DEPLOYMENT_TARGET"
+    !isEmpty(report_message): qtConfReportPadded($$1, $$report_message)
+}