Moving sources to src part 1: Move files.

This only move files without adjusting any paths.

This moves:
- lib/quick -> src/webengine/api (API files)
  lib/quick -> src/webengine (other files)
  This contains the main QtWebEngine module library since
  <ec7b2ee70a8b2db7fb87f50671a001ddd54697b0>.
- lib/widgets -> src/webenginewidgets
  Also rename this directory to match its module name and rename Api to api.
- lib -> src/core
- process -> src/process
- resources -> src/core/resources
- tools/* -> tools/scripts/

The build directory is spread as follow:
- build/build.pro -> src/core/gyp_run.pro
- build/qmake_extras/* -> src/core/ (for the host and target .pro files)
- build/qmake -> tools/qmake
- Build related scripts -> tools/buildscripts

Change-Id: I0cded1de772c99c0c1da6536c9afea353236b4a1
Reviewed-by: Zeno Albisser <zeno.albisser@digia.com>
Reviewed-by: Pierre Rossi <pierre.rossi@gmail.com>
Reviewed-by: Andras Becsi <andras.becsi@digia.com>

1 files changed, 47 insertions, 0 deletions

diff --git a/src/webenginewidgets/webenginewidgets.pro b/src/webenginewidgets/webenginewidgets.pro
new file mode 100644
index 000000000..3338e0cf7
--- /dev/null
+++ b/src/webenginewidgets/webenginewidgets.pro
@@ -0,0 +1,47 @@
+# Use Qt5 module system
+load(qt_build_config)
+
+TEMPLATE = lib
+TARGET = QtWebEngineWidgets
+
+MODULE = webenginewidgets
+
+# For our export macros
+DEFINES += QT_BUILD_WEBENGINEWIDGETS_LIB
+
+QT += widgets
+QT_PRIVATE += widgets-private gui-private core-private
+
+# FIXME: all this should eventually be turned into QT += webenginecore
+macx:LIBPATH = $$getOutDir()/$$getConfigDir()
+else:LIBPATH = $$getOutDir()/$$getConfigDir()/lib
+LIBS_PRIVATE += -lQt5WebEngineCore -L$$LIBPATH
+QMAKE_RPATHDIR += $$LIBPATH
+
+DESTDIR = $$LIBPATH
+
+INCLUDEPATH += Api ../
+
+SOURCES = \
+        Api/qwebenginehistory.cpp \
+        Api/qwebenginepage.cpp \
+        Api/qwebengineview.cpp\
+        render_widget_host_view_qt_delegate_widget.cpp
+
+HEADERS = \
+        Api/qtwebenginewidgetsglobal.h \
+        Api/qwebenginehistory.h \
+        Api/qwebenginepage.h \
+        Api/qwebengineview.h \
+        Api/qwebengineview_p.h \
+        render_widget_host_view_qt_delegate_widget.h
+
+load(qt_module)
+
+# QNX ld only supports staging-relative rpath values and can't use the rpath specified above.
+# Instead, append an appropriate rpath-link to lib_qt_webenginewidgets.pri.
+qnx:!build_pass {
+    local_build_rpath_link = "QMAKE_RPATHLINKDIR += $$LIBPATH"
+    # MODULE_PRI is defined in qt_module_pris.prf
+    write_file($$MODULE_PRI, local_build_rpath_link, append)
+}