Add WebEngineView::save() convenience API

Add the convenience method QQuickWebEngineView::save for saving pages without
the need to explicitly handle download requests.

Task-number: QTBUG-56093
Change-Id: I67909fdca6472d1ea9b32e0f89c1ab90219bca3b
Reviewed-by: Leena Miettinen <riitta-leena.miettinen@qt.io>
Reviewed-by: Michal Klocek <michal.klocek@qt.io>

2 files changed, 124 insertions, 0 deletions

diff --git a/tests/auto/quick/qmltests/CMakeLists.txt b/tests/auto/quick/qmltests/CMakeLists.txt
index ecbb6ac3e..acd783bd5 100644
--- a/tests/auto/quick/qmltests/CMakeLists.txt
+++ b/tests/auto/quick/qmltests/CMakeLists.txt
@@ -60,6 +60,7 @@ set(testList
     tst_userScripts.qml
     tst_userScriptCollection.qml
     tst_viewSource.qml
+    tst_save.qml
 )
 
 if(QT_FEATURE_webengine_webchannel)
diff --git a/tests/auto/quick/qmltests/data/tst_save.qml b/tests/auto/quick/qmltests/data/tst_save.qml
new file mode 100644
index 000000000..9757f8fac
--- /dev/null
+++ b/tests/auto/quick/qmltests/data/tst_save.qml
@@ -0,0 +1,123 @@
+import QtQuick
+import QtTest
+import QtWebEngine
+import Test.util
+
+TestWebEngineView {
+    id: webEngineView
+    width: 200
+    height: 200
+    profile: testSaveProfile
+
+    property url downloadUrl: ""
+    property int totalBytes: 0
+    property int receivedBytes: 0
+    property string downloadDir: ""
+    property string downloadFileName: ""
+    property var downloadState: []
+    property int savePageFormat: WebEngineDownloadRequest.MimeHtmlSaveFormat;
+
+    TempDir {
+        id: tempDir
+    }
+
+    SignalSpy {
+        id: downLoadRequestedSpy
+        target: testSaveProfile
+        signalName: "downloadRequested"
+    }
+
+    SignalSpy {
+        id: downloadFinishedSpy
+        target: testSaveProfile
+        signalName: "downloadFinished"
+    }
+
+    WebEngineProfile {
+        id: testSaveProfile
+
+        onDownloadRequested: function(download) {
+            downloadState.push(download.state)
+            downloadUrl = download.url
+            savePageFormat = download.savePageFormat
+            downloadDir = download.downloadDirectory;
+            downloadFileName = download.downloadFileName
+        }
+        onDownloadFinished: function(download) {
+            receivedBytes = download.receivedBytes
+            totalBytes = download.totalBytes
+            downloadState.push(download.state)
+        }
+    }
+
+    TestCase {
+        name: "WebEngineViewSave"
+
+        function verifyData() {
+            var isDataValid = false
+            webEngineView.runJavaScript("(function() {" +
+                                        "var title = document.title.toString();" +
+                                        "var body = document.body.innerText;" +
+                                        " return title === \"Test page 1\" && body.includes(\"Hello.\")" +
+                                        "})();", function(result) {
+                isDataValid = result;
+            });
+            tryVerify(function() { return isDataValid });
+            return isDataValid;
+        }
+
+        function init() {
+            downLoadRequestedSpy.clear()
+            downloadFinishedSpy.clear()
+            totalBytes = 0
+            receivedBytes = 0
+            downloadDir = ""
+            downloadFileName = ""
+            downloadState = []
+            downloadUrl = ""
+        }
+
+        function test_savePage_data() {
+            return [
+                   { tag: "SingleHtmlSaveFormat", savePageFormat: WebEngineDownloadRequest.SingleHtmlSaveFormat },
+                   { tag: "CompleteHtmlSaveFormat", savePageFormat: WebEngineDownloadRequest.CompleteHtmlSaveFormat },
+                   { tag: "MimeHtmlSaveFormat", savePageFormat: WebEngineDownloadRequest.MimeHtmlSaveFormat },
+            ];
+        }
+
+        function test_savePage(row) {
+            var saveFormat = row.savePageFormat
+
+            var fileDir = tempDir.path()
+            var fileName = "saved_page.html"
+            var filePath = fileDir + "/"+ fileName
+
+            // load data to view
+            webEngineView.url = Qt.resolvedUrl("test1.html")
+            verify(webEngineView.waitForLoadSucceeded())
+            verify(verifyData())
+
+            webEngineView.save(filePath, saveFormat)
+            downLoadRequestedSpy.wait()
+            compare(downLoadRequestedSpy.count, 1)
+            compare(downloadUrl, webEngineView.url)
+            compare(savePageFormat, saveFormat)
+            compare(downloadDir, fileDir)
+            compare(downloadFileName, fileName)
+            compare(downloadState[0], WebEngineDownloadRequest.DownloadInProgress)
+            downloadFinishedSpy.wait()
+            compare(downloadFinishedSpy.count, 1)
+            compare(totalBytes, receivedBytes)
+            compare(downloadState[1], WebEngineDownloadRequest.DownloadCompleted)
+
+            // load some other data
+            webEngineView.url = Qt.resolvedUrl("about:blank")
+            verify(webEngineView.waitForLoadSucceeded())
+
+            // load save file to view
+            webEngineView.url = Qt.resolvedUrl(filePath)
+            verify(webEngineView.waitForLoadSucceeded())
+            verify(verifyData())
+        }
+    }
+}