Add spellchecker support and qwebengine_covert_dict to cmake

Add spellchecker dictionary conversion tool.
Change scope of gn object imported variables to function scope.

Pick-to: 6.2
Change-Id: Ice579a89e20b80034b675e7f767a774100478472
Reviewed-by: Allan Sandfeld Jensen <allan.jensen@qt.io>

1 files changed, 49 insertions, 0 deletions

diff --git a/tests/auto/widgets/spellchecking/CMakeLists.txt b/tests/auto/widgets/spellchecking/CMakeLists.txt
new file mode 100644
index 000000000..afed7e28b
--- /dev/null
+++ b/tests/auto/widgets/spellchecking/CMakeLists.txt
@@ -0,0 +1,49 @@
+include(../../util/util.cmake)
+
+qt_internal_add_test(tst_spellchecking
+    SOURCES
+        tst_spellchecking.cpp
+    LIBRARIES
+        Qt::WebEngineWidgets
+        Test::Util
+)
+
+qt_internal_add_resource(tst_spellchecking "tst_spellchecking"
+    PREFIX
+        "/"
+    FILES
+        "resources/index.html"
+)
+
+file(GLOB_RECURSE dicts
+    RELATIVE ${CMAKE_CURRENT_LIST_DIR}/dict
+    *.dic
+)
+
+if(QT_GENERATOR_IS_MULTI_CONFIG)
+    set(spellcheckerDir ${CMAKE_CURRENT_BINARY_DIR}/dict/qtwebengine_dictionaries)
+else()
+    set(spellcheckerDir ${CMAKE_CURRENT_BINARY_DIR}/qtwebengine_dictionaries)
+endif()
+
+foreach(dictFile ${dicts})
+    get_filename_component(dictName ${dictFile} NAME_WE)
+    add_custom_command(TARGET tst_spellchecking
+        PRE_BUILD
+        COMMAND ${CMAKE_COMMAND} -E make_directory ${spellcheckerDir}
+        COMMAND  $<TARGET_FILE:${QT_CMAKE_EXPORT_NAMESPACE}::qwebengine_convert_dict>
+        ${CMAKE_CURRENT_SOURCE_DIR}/dict/${dictFile}
+        ${spellcheckerDir}/${dictName}.bdic
+        COMMENT "Running qwebengine_convert_dict"
+    )
+endforeach()
+
+# copy dictionaries to $<CONFIG> build dir
+if(QT_GENERATOR_IS_MULTI_CONFIG)
+    add_custom_command(TARGET tst_spellchecking
+       POST_BUILD
+       COMMAND ${CMAKE_COMMAND} -E echo Copying dictionares
+       COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_BINARY_DIR}/dict
+       ${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>
+    )
+endif()