summaryrefslogtreecommitdiffstats
path: root/src/buildtools
diff options
context:
space:
mode:
Diffstat (limited to 'src/buildtools')
-rw-r--r--src/buildtools/buildtools.pro20
-rw-r--r--src/buildtools/configure_host.pro65
-rw-r--r--src/buildtools/configure_target.pro33
-rw-r--r--src/buildtools/gn.pro41
-rw-r--r--src/buildtools/ninja.pro23
5 files changed, 0 insertions, 182 deletions
diff --git a/src/buildtools/buildtools.pro b/src/buildtools/buildtools.pro
deleted file mode 100644
index 1366d18d5..000000000
--- a/src/buildtools/buildtools.pro
+++ /dev/null
@@ -1,20 +0,0 @@
-TEMPLATE = subdirs
-
-linux {
- # configure_host.pro and configure_target.pro are phony pro files that
- # extract things like compiler and linker from qmake.
- # Only used on Linux as it is only important for cross-building and alternative compilers.
- configure_host.file = configure_host.pro
- configure_target.file = configure_target.pro
- configure_target.depends = configure_host
- gn.depends += configure_target
-
- SUBDIRS += configure_host configure_target
-}
-
-ninja.file = ninja.pro
-SUBDIRS += ninja
-
-gn.file = gn.pro
-gn.depends = ninja
-SUBDIRS += gn
diff --git a/src/buildtools/configure_host.pro b/src/buildtools/configure_host.pro
deleted file mode 100644
index dd0d3e327..000000000
--- a/src/buildtools/configure_host.pro
+++ /dev/null
@@ -1,65 +0,0 @@
-# Prevent generating a makefile that attempts to create a lib
-TEMPLATE = aux
-
-# Pick up the host toolchain
-option(host_build)
-
-GN_HOST_CPU = $$gnArch($$QT_ARCH)
-!isEmpty(QT_TARGET_ARCH): GN_TARGET_CPU = $$gnArch($$QT_TARGET_ARCH)
-else: GN_TARGET_CPU = $$GN_HOST_CPU
-GN_OS = $$gnOS()
-
-clang: GN_CLANG = true
-else: GN_CLANG = false
-
-use_gold_linker: GN_USE_GOLD=true
-else: GN_USE_GOLD=false
-
-GN_V8_HOST_CPU = $$GN_HOST_CPU
-contains(GN_TARGET_CPU, "arm")|contains(GN_TARGET_CPU, "mipsel")|contains(GN_TARGET_CPU, "x86") {
- # The v8 snapshot need a host that matches bitwidth, so we build makesnapshot to 32-bit variants of host.
- contains(GN_V8_HOST_CPU, x64): GN_V8_HOST_CPU = "x86"
- else: contains(GN_V8_HOST_CPU, arm64): GN_V8_HOST_CPU = "arm"
- else: contains(GN_V8_HOST_CPU, mips64el): GN_V8_HOST_CPU = "mipsel"
-}
-
-GN_HOST_EXTRA_CPPFLAGS = $$(GN_HOST_TOOLCHAIN_EXTRA_CPPFLAGS)
-
-# We always use the gcc_toolchain, because clang_toolchain is just
-# a broken wrapper around it for Google's custom clang binaries.
-GN_CONTENTS = \
-"import(\"//build/config/sysroot.gni\")" \
-"import(\"//build/toolchain/gcc_toolchain.gni\")" \
-"gcc_toolchain(\"host\") {" \
-" cc = \"$$which($$QMAKE_CC)\" " \
-" cxx = \"$$which($$QMAKE_CXX)\" " \
-" ld = \"$$which($$QMAKE_LINK)\" " \
-" ar = \"$$which(ar)\" " \
-" nm = \"$$which(nm)\" " \
-" extra_cppflags = \"$$GN_HOST_EXTRA_CPPFLAGS\" " \
-" toolchain_args = { " \
-" current_os = \"$$GN_OS\" " \
-" current_cpu = \"$$GN_HOST_CPU\" " \
-" is_clang = $$GN_CLANG " \
-" use_gold = $$GN_USE_GOLD " \
-" } " \
-"}" \
-"gcc_toolchain(\"v8_snapshot\") {" \
-" cc = \"$$which($$QMAKE_CC)\" " \
-" cxx = \"$$which($$QMAKE_CXX)\" " \
-" ld = \"$$which($$QMAKE_LINK)\" " \
-" ar = \"$$which(ar)\" " \
-" nm = \"$$which(nm)\" " \
-" toolchain_args = { " \
-" current_os = \"$$GN_OS\" " \
-" current_cpu = \"$$GN_V8_HOST_CPU\" " \
-" v8_current_cpu = \"$$GN_TARGET_CPU\" " \
-" is_clang = $$GN_CLANG " \
-" use_gold = $$GN_USE_GOLD " \
-" } " \
-" } "
-
-GN_FILE = $$OUT_PWD/../toolchain/BUILD.gn
-!build_pass {
- write_file($$GN_FILE, GN_CONTENTS)
-}
diff --git a/src/buildtools/configure_target.pro b/src/buildtools/configure_target.pro
deleted file mode 100644
index 31aa283f6..000000000
--- a/src/buildtools/configure_target.pro
+++ /dev/null
@@ -1,33 +0,0 @@
-# Prevent generating a makefile that attempts to create a lib
-TEMPLATE = aux
-
-GN_CPU = $$gnArch($$QT_ARCH)
-GN_OS = $$gnOS()
-
-clang: GN_CLANG = true
-else: GN_CLANG = false
-
-use_gold_linker: GN_USE_GOLD=true
-else: GN_USE_GOLD=false
-
-GN_CONTENTS = \
-"gcc_toolchain(\"target\") {" \
-" cc = \"$$which($$QMAKE_CC)\" " \
-" cxx = \"$$which($$QMAKE_CXX)\" " \
-" ld = \"$$which($$QMAKE_LINK)\" " \
-" ar = \"$$which($${CROSS_COMPILE}ar)\" " \
-" nm = \"$$which($${CROSS_COMPILE}nm)\" " \
-" toolchain_args = { " \
-" current_os = \"$$GN_OS\" " \
-" current_cpu = \"$$GN_CPU\" " \
-" is_clang = $$GN_CLANG " \
-" use_gold = $$GN_USE_GOLD " \
-" } " \
-"}"
-
-GN_FILE = $$OUT_PWD/../toolchain/BUILD.gn
-!build_pass {
- write_file($$GN_FILE, GN_CONTENTS, append)
-}
-
-QMAKE_DISTCLEAN += $$GN_FILE
diff --git a/src/buildtools/gn.pro b/src/buildtools/gn.pro
deleted file mode 100644
index b6bf9cfc4..000000000
--- a/src/buildtools/gn.pro
+++ /dev/null
@@ -1,41 +0,0 @@
-TEMPLATE = aux
-option(host_build)
-
-!debug_and_release: CONFIG += release
-
-include($$QTWEBENGINE_OUT_ROOT/src/core/qtwebenginecore-config.pri)
-QT_FOR_CONFIG += webenginecore-private
-
-build_pass|!debug_and_release {
- !qtConfig(webengine-system-gn): CONFIG(release, debug|release) {
- buildgn.target = build_gn
- out = $$gnPath()
- out_path = $$dirname(out)
- !qtConfig(webengine-system-ninja): ninja_path = $$ninjaPath()
- else: ninja_path="ninja"
- # check if it is not already build
- !exists($$out) {
- src_3rd_party_dir = $$absolute_path("$${getChromiumSrcDir()}/../", "$$QTWEBENGINE_ROOT")
- gn_bootstrap = $$system_path($$absolute_path(gn/build/gen.py, $$src_3rd_party_dir))
-
- gn_gen_args = --no-last-commit-position --out-path $$out_path \
- --cc \"$$which($$QMAKE_CC)\" --cxx \"$$which($$QMAKE_CXX)\" \
- --ld \"$$which($$QMAKE_LINK)\"
-
- msvc:!clang_cl: gn_gen_args += --use-lto
-
- gn_configure = $$system_quote($$gn_bootstrap) $$gn_gen_args
- macos {
- gn_configure += --isysroot \"$$QMAKE_MAC_SDK_PATH\"
- }
- message($$gn_configure)
- !system("$$pythonPathForSystem() $$gn_configure") {
- error("GN generation error!")
- }
- !system("cd $$system_quote($$system_path($$out_path)) && $$ninja_path $$basename(out)" ) {
- error("GN build error!")
- }
- }
- QMAKE_DISTCLEAN += $$out
- }
-}
diff --git a/src/buildtools/ninja.pro b/src/buildtools/ninja.pro
deleted file mode 100644
index 6382d6cfb..000000000
--- a/src/buildtools/ninja.pro
+++ /dev/null
@@ -1,23 +0,0 @@
-TEMPLATE = aux
-
-!debug_and_release: CONFIG += release
-
-include($$QTWEBENGINE_OUT_ROOT/src/core/qtwebenginecore-config.pri)
-QT_FOR_CONFIG += webenginecore-private
-
-build_pass|!debug_and_release {
- !qtConfig(webengine-system-ninja): CONFIG(release, debug|release) {
- out = $$ninjaPath()
- # check if it is not already build
- !exists($$out) {
- mkpath($$dirname(out))
- src_3rd_party_dir = $$absolute_path("$${getChromiumSrcDir()}/../", "$$QTWEBENGINE_ROOT")
- ninja_configure = $$system_quote($$system_path($$absolute_path(ninja/configure.py, $$src_3rd_party_dir)))
- !system("cd $$system_quote($$system_path($$dirname(out))) && $$pythonPathForSystem() $$ninja_configure --bootstrap") {
- error("NINJA build error!")
- }
- }
- QMAKE_DISTCLEAN += $$out
- }
-}
-
generated by cgit v1.2.3 (git 2.25.1) at 2024-06-20 00:20:03 +0000