blob: 2dc1eefcd5a429feb479c1d4030a018d7f4dd66f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
include($$QTWEBENGINE_OUT_ROOT/src/core/qtwebenginecore-config.pri) # workaround for QTBUG-68093
QT_FOR_CONFIG += webenginecore webenginecore-private
TEMPLATE = subdirs
SUBDIRS += \
defaultsurfaceformat \
devtools \
faviconmanager \
loadsignals \
offscreen \
origins \
proxy \
proxypac \
schemes \
shutdown \
qwebenginedownloaditem \
qwebenginepage \
qwebenginehistory \
qwebengineprofile \
qwebenginescript \
qwebenginesettings \
qwebengineview
# Synthetic touch events are not supported on macOS
!macos: SUBDIRS += touchinput
qtConfig(accessibility) {
SUBDIRS += accessibility
}
qtConfig(webengine-printing-and-pdf) {
SUBDIRS += printing
}
qtConfig(ssl) {
SUBDIRS += certificateerror
}
qtConfig(webengine-spellchecker):!cross_compile {
!qtConfig(webengine-native-spellchecker) {
SUBDIRS += spellchecking
} else {
message("Spellcheck test will not be built because it depends on usage of Hunspell dictionaries.")
}
}
# QTBUG-60268
boot2qt: SUBDIRS -= accessibility defaultsurfaceformat devtools \
qwebenginepage \
qwebengineprofile \
qwebengineview
win32: SUBDIRS -= offscreen
|